path: root/src/keytrans/pem2openpgp

#!/usr/bin/perl -w -T

# pem2openpgp: take a PEM-encoded RSA private-key on standard input, a
# User ID as the first argument, and generate an OpenPGP certificate
# from it.

# Authors:
#  Jameson Rollins <jrollins@finestructure.net>
#  Daniel Kahn Gillmor <dkg@fifthhorseman.net>

# Started on: 2009-01-07 02:01:19-0500

# License: GPL v3 or later (we may need to adjust this given that this
# connects to OpenSSL via perl)

use strict;
use warnings;
use Crypt::OpenSSL::RSA;
use Crypt::OpenSSL::Bignum;
use Digest::SHA1;
use MIME::Base64;

## make sure all length() and substr() calls use bytes only:
use bytes;

# make an old-style packet out of the given packet type and body.
# old-style  (see RFC 4880 section 4.2)
sub make_packet {
  my $type = shift;
  my $body = shift;

# FIXME: yet another length():
  my $len = length($body);

  my $lenbytes;
  my $lencode;

  if ($len < 2**8) {
    $lenbytes = 0;
    $lencode = 'C';
  } elsif ($len < 2**16) {
    $lenbytes = 1;
    $lencode = 'n';
  } elsif ($len < 2**31) {
    ## not testing against full 32 bits because i don't want to deal
    ## with potential overflow.
    $lenbytes = 2;
    $lencode = 'N';
  } else {
    ## what the hell do we do here?
    $lenbytes = 3;
    $lencode = '';
  }

  return pack('C'.$lencode, 0x80 + ($type * 4) + $lenbytes, $len).
    $body;
}


# takes a Crypt::OpenSSL::Bignum, returns it formatted as OpenPGP MPI
# (RFC 4880 section 3.2)
sub mpi_pack {
  my $num = shift;

  my $hex = $num->to_hex();

  my $mpilen = length($hex)*4;

# this is a kludgy way to get the number of bits in the first byte:
  my $bitsinfirstbyte = length(sprintf("%b", hex(substr $hex, 0, 2)));

  $mpilen -= (8 - $bitsinfirstbyte);

  return pack('n', $mpilen).$num->to_bin();
}
# FIXME: genericize this to accept either RSA or DSA keys:
sub make_rsa_key_body {
  my $key = shift;
  my $timestamp = shift;

  my ($n, $e) = $key->get_key_parameters();

  return
    pack('CN', 4, $timestamp).
      pack('C', 1). # RSA
    mpi_pack($n).
      mpi_pack($e);

}

# expects an RSA key (public or private) and a timestamp
sub fingerprint {
  my $key = shift;
  my $timestamp = shift;

  my $rsabody = make_rsa_key_body($key, $timestamp);

  return Digest::SHA1::sha1_hex(pack('Cn', 0x99, length($rsabody)).$rsabody);
}

my $holdTerminator = $/;
undef $/;
my $buf = <STDIN>;


my $rsa = Crypt::OpenSSL::RSA->new_private_key($buf);

$rsa->use_sha1_hash();
$rsa->use_no_padding();

if (! $rsa->check_key()) {
  die "key does not check";
}

my $uid = 'fake key (do not use) <test@example.org>';



my $version = pack('C', 4);
# strong assertion of identity:
my $sigtype = pack('C', 0x13);
# RSA
my $pubkey_algo = pack('C', 1);
# SHA1
my $hash_algo = pack('C', 2);



my $timestamp = 1231003584;

my $creation_time_packet = pack('CCN', 5, 2, $timestamp);


# usage: signing and certification:
my $flags = 0x03;
my $usage_packet = pack('CCC', 2, 27, $flags);


# expire in 2 days:
my $expires_in = 86400*2;
my $expiration_packet = pack('CCN', 5, 9, $expires_in);


# prefer AES-256, AES-192, AES-128, CAST5, 3DES:
my $pref_sym_algos = pack('CCCCCCC', 6, 11, 9, 8, 7, 3, 2);

# prefer SHA-1, SHA-256, RIPE-MD/160
my $pref_hash_algos = pack('CCCCC', 4, 21, 2, 8, 3);

# prefer ZLIB, BZip2, ZIP
my $pref_zip_algos = pack('CCCCC', 4, 22, 2, 3, 1);

# we support the MDC feature:
my $features = pack('CCC', 2, 30, 1);

# keyserver preference: only owner modify (???):
my $keyserver_pref = pack('CCC', 2, 23, 0x80);

my $subpackets_to_be_hashed =
  $creation_time_packet.
  $usage_packet.
  $expiration_packet.
  $pref_sym_algos.
  $pref_hash_algos.
  $pref_zip_algos.
  $features.
  $keyserver_pref;

#FIXME: what's the right way to get length()?
my $subpacket_octets = pack('n', length($subpackets_to_be_hashed));

my $sig_data_to_be_hashed =
  $version.
  $sigtype.
  $pubkey_algo.
  $hash_algo.
  $subpacket_octets.
  $subpackets_to_be_hashed;

my $pubkey = make_rsa_key_body($rsa, $timestamp);

#open(KEYFILE, "</home/wt215/gpg-test/key-data");
my $key_data = make_packet(6, $pubkey);

# take the last 16 characters of the fingerprint as the keyid:
my $keyid = substr(fingerprint($rsa, $timestamp), 40 - 16, 16);

# the v4 signature trailer is:

# version number, literal 0xff, and then a 4-byte count of the
# signature data itself.
my $trailer = pack('CCN', 4, 0xff, length($sig_data_to_be_hashed));

# FIXME: length() is probably not right here either in the event that
# the uid uses unicode.
my $uid_data =
  pack('CN', 0xb4, length($uid)).
  $uid;

my $datatosign =
  $key_data.
  $uid_data.
  $sig_data_to_be_hashed.
  $trailer;

my $data_hash = Digest::SHA1::sha1_hex($datatosign);


my $issuer_packet = pack('CCH16', 9, 16, $keyid);

my $sig = Crypt::OpenSSL::Bignum->new_from_bin($rsa->sign($datatosign));

my $sig_body =
  $sig_data_to_be_hashed.
# FIXME: another dubious length() call.
  pack('n', length($issuer_packet)).
  $issuer_packet.
  pack('n', hex(substr($data_hash, 0, 4))).
  mpi_pack($sig);

print make_packet(6, $pubkey);
print make_packet(13, $uid);
print make_packet(2, $sig_body);

$/ = $holdTerminator;