32 files changed, 0 insertions, 0 deletions

path: root/perl/IkiWiki/Plugin/farbar.pm

#!/usr/bin/perl
# Farbar plugin.
# by Jonas Smedegaard <dr@jones.dk>
# Heavily based on Sidebar by Tuomo Valkonen <tuomov at iki dot fi> 

package IkiWiki::Plugin::farbar;

use warnings;
use strict;
use IkiWiki 2.00;

sub import { #{{{
    hook(type => "pagetemplate", id => "farbar", call => \&pagetemplate);
} # }}}

sub farbar_content ($) { #{{{
    my $page=shift;
    
    my $farbar_page=bestlink($page, "farbar") || return;
    my $farbar_file=$pagesources{$farbar_page} || return;
    my $farbar_type=pagetype($farbar_file);
    
    if (defined $farbar_type) {
        # FIXME: This isn't quite right; it won't take into account
        # adding a new farbar page. So adding such a page
        # currently requires a wiki rebuild.
        add_depends($page, $farbar_page);

        my $content=readfile(srcfile($farbar_file));
        return unless length $content;
        return IkiWiki::htmlize($farbar_page, $page, $farbar_type,
               IkiWiki::linkify($farbar_page, $page,
               IkiWiki::preprocess($farbar_page, $page,
               IkiWiki::filter($farbar_page, $page, $content))));
    }

} # }}}

sub pagetemplate (@) { #{{{
    my %params=@_;

    my $page=$params{page};
    my $template=$params{template};
    
    if ($template->query(name => "farbar")) {
        my $content=farbar_content($page);
        if (defined $content && length $content) {
                $template->param(farbar => $content);
        }
    }
} # }}}

1