path: root/IkiWiki/Plugin/meta.pm

#!/usr/bin/perl
# Ikiwiki metadata plugin.
package IkiWiki::Plugin::meta;

use warnings;
use strict;
use IkiWiki;

my %meta;
my %title;

sub import { #{{{
    IkiWiki::hook(type => "preprocess", id => "meta", 
        call => \&preprocess);
    IkiWiki::hook(type => "filter", id => "meta", 
        call => \&filter);
    IkiWiki::hook(type => "pagetemplate", id => "meta", 
        call => \&pagetemplate);
} # }}}

sub filter (@) { #{{{
    my %params=@_;
    
    $meta{$params{page}}='';

    return $params{content};
} # }}}

sub preprocess (@) { #{{{
    if (! @_) {
        return "";
    }
    my %params=@_;
    my $key=shift;
    my $value=$params{$key};
    delete $params{$key};
    my $page=$params{page};
    delete $params{page};
    delete $params{destpage};

    eval q{use HTML::Entities};
    # Always dencode, even if encoding later, since it might not be
    # fully encoded.
    $value=decode_entities($value);

    if ($key eq 'link') {
        if (%params) {
            $meta{$page}.="<link href=\"".encode_entities($value)."\" ".
                join(" ", map { encode_entities($_)."=\"".encode_entities(decode_entities($params{$_}))."\"" } keys %params).
                " />\n";
        }
        else {
            # hidden WikiLink
            push @{$IkiWiki::links{$page}}, $value;
        }
    }
    elsif ($key eq 'title') {
        $title{$page}=$value;
    }
    else {
        $meta{$page}.="<meta name=\"".encode_entities($key).
            "\" content=\"".encode_entities($value)."\" />\n";
    }

    return "";
} # }}}

sub pagetemplate (@) { #{{{
    my %params=@_;
        my $page=$params{page};
        my $template=$params{template};

    $template->param(meta => $meta{$page})
        if exists $meta{$page} && $template->query(name => "meta");
    $template->param(title => $title{$page})
        if exists $title{$page} && $template->query(name => "title");
} # }}}

1