summaryrefslogtreecommitdiff
path: root/IkiWiki/Plugin/inline.pm
blob: 2d47cb4befdfd8532904552dab2622c704c08c2e (plain)
  1. #!/usr/bin/perl
  2. # Page inlining and blogging.
  3. package IkiWiki::Plugin::inline;
  4. use warnings;
  5. use strict;
  6. use Encode;
  7. use IkiWiki 3.00;
  8. use URI;
  9. my %knownfeeds;
  10. my %page_numfeeds;
  11. my @inline;
  12. my $nested=0;
  13. sub import {
  14. hook(type => "getopt", id => "inline", call => \&getopt);
  15. hook(type => "getsetup", id => "inline", call => \&getsetup);
  16. hook(type => "checkconfig", id => "inline", call => \&checkconfig);
  17. hook(type => "sessioncgi", id => "inline", call => \&sessioncgi);
  18. hook(type => "preprocess", id => "inline",
  19. call => \&IkiWiki::preprocess_inline);
  20. hook(type => "pagetemplate", id => "inline",
  21. call => \&IkiWiki::pagetemplate_inline);
  22. hook(type => "format", id => "inline", call => \&format, first => 1);
  23. # Hook to change to do pinging since it's called late.
  24. # This ensures each page only pings once and prevents slow
  25. # pings interrupting page builds.
  26. hook(type => "change", id => "inline", call => \&IkiWiki::pingurl);
  27. }
  28. sub getopt () {
  29. eval q{use Getopt::Long};
  30. error($@) if $@;
  31. Getopt::Long::Configure('pass_through');
  32. GetOptions(
  33. "rss!" => \$config{rss},
  34. "atom!" => \$config{atom},
  35. "allowrss!" => \$config{allowrss},
  36. "allowatom!" => \$config{allowatom},
  37. "pingurl=s" => sub {
  38. push @{$config{pingurl}}, $_[1];
  39. },
  40. );
  41. }
  42. sub getsetup () {
  43. return
  44. plugin => {
  45. safe => 1,
  46. rebuild => undef,
  47. section => "core",
  48. },
  49. rss => {
  50. type => "boolean",
  51. example => 0,
  52. description => "enable rss feeds by default?",
  53. safe => 1,
  54. rebuild => 1,
  55. },
  56. atom => {
  57. type => "boolean",
  58. example => 0,
  59. description => "enable atom feeds by default?",
  60. safe => 1,
  61. rebuild => 1,
  62. },
  63. allowrss => {
  64. type => "boolean",
  65. example => 0,
  66. description => "allow rss feeds to be used?",
  67. safe => 1,
  68. rebuild => 1,
  69. },
  70. allowatom => {
  71. type => "boolean",
  72. example => 0,
  73. description => "allow atom feeds to be used?",
  74. safe => 1,
  75. rebuild => 1,
  76. },
  77. pingurl => {
  78. type => "string",
  79. example => "http://rpc.technorati.com/rpc/ping",
  80. description => "urls to ping (using XML-RPC) on feed update",
  81. safe => 1,
  82. rebuild => 0,
  83. },
  84. }
  85. sub checkconfig () {
  86. if (($config{rss} || $config{atom}) && ! length $config{url}) {
  87. error(gettext("Must specify url to wiki with --url when using --rss or --atom"));
  88. }
  89. if ($config{rss}) {
  90. push @{$config{wiki_file_prune_regexps}}, qr/\.rss$/;
  91. }
  92. if ($config{atom}) {
  93. push @{$config{wiki_file_prune_regexps}}, qr/\.atom$/;
  94. }
  95. if (! exists $config{pingurl}) {
  96. $config{pingurl}=[];
  97. }
  98. }
  99. sub format (@) {
  100. my %params=@_;
  101. # Fill in the inline content generated earlier. This is actually an
  102. # optimisation.
  103. $params{content}=~s{<div class="inline" id="([^"]+)"></div>}{
  104. delete @inline[$1,]
  105. }eg;
  106. return $params{content};
  107. }
  108. sub sessioncgi ($$) {
  109. my $q=shift;
  110. my $session=shift;
  111. if ($q->param('do') eq 'blog') {
  112. my $page=titlepage(decode_utf8($q->param('title')));
  113. $page=~s/(\/)/"__".ord($1)."__"/eg; # don't create subdirs
  114. # if the page already exists, munge it to be unique
  115. my $from=$q->param('from');
  116. my $add="";
  117. while (exists $IkiWiki::pagecase{lc($from."/".$page.$add)}) {
  118. $add=1 unless length $add;
  119. $add++;
  120. }
  121. $q->param('page', $page.$add);
  122. # now go create the page
  123. $q->param('do', 'create');
  124. # make sure the editpage plugin in loaded
  125. if (IkiWiki->can("cgi_editpage")) {
  126. IkiWiki::cgi_editpage($q, $session);
  127. }
  128. else {
  129. error(gettext("page editing not allowed"));
  130. }
  131. exit;
  132. }
  133. }
  134. # Back to ikiwiki namespace for the rest, this code is very much
  135. # internal to ikiwiki even though it's separated into a plugin.
  136. package IkiWiki;
  137. my %toping;
  138. my %feedlinks;
  139. sub preprocess_inline (@) {
  140. my %params=@_;
  141. if (! exists $params{pages} && ! exists $params{pagenames}) {
  142. error gettext("missing pages parameter");
  143. }
  144. my $raw=yesno($params{raw});
  145. my $archive=yesno($params{archive});
  146. my $rss=(($config{rss} || $config{allowrss}) && exists $params{rss}) ? yesno($params{rss}) : $config{rss};
  147. my $atom=(($config{atom} || $config{allowatom}) && exists $params{atom}) ? yesno($params{atom}) : $config{atom};
  148. my $quick=exists $params{quick} ? yesno($params{quick}) : 0;
  149. my $feeds=! $nested && (exists $params{feeds} ? yesno($params{feeds}) : !$quick && ! $raw);
  150. my $emptyfeeds=exists $params{emptyfeeds} ? yesno($params{emptyfeeds}) : 1;
  151. my $feedonly=yesno($params{feedonly});
  152. if (! exists $params{show} && ! $archive) {
  153. $params{show}=10;
  154. }
  155. if (! exists $params{feedshow} && exists $params{show}) {
  156. $params{feedshow}=$params{show};
  157. }
  158. my $desc;
  159. if (exists $params{description}) {
  160. $desc = $params{description}
  161. }
  162. else {
  163. $desc = $config{wikiname};
  164. }
  165. my $actions=yesno($params{actions});
  166. if (exists $params{template}) {
  167. $params{template}=~s/[^-_a-zA-Z0-9]+//g;
  168. }
  169. else {
  170. $params{template} = $archive ? "archivepage" : "inlinepage";
  171. }
  172. my @list;
  173. if (exists $params{pagenames}) {
  174. foreach my $p (qw(sort pages)) {
  175. if (exists $params{$p}) {
  176. error sprintf(gettext("the %s and %s parameters cannot be used together"),
  177. "pagenames", $p);
  178. }
  179. }
  180. @list = map { bestlink($params{page}, $_) }
  181. split ' ', $params{pagenames};
  182. if (yesno($params{reverse})) {
  183. @list=reverse(@list);
  184. }
  185. foreach my $p (@list) {
  186. add_depends($params{page}, $p, deptype($quick ? "presence" : "content"));
  187. }
  188. }
  189. else {
  190. my $num=0;
  191. if ($params{show}) {
  192. $num=$params{show};
  193. }
  194. if ($params{feedshow} && $num < $params{feedshow} && $num > 0) {
  195. $num=$params{feedshow};
  196. }
  197. if ($params{skip} && $num) {
  198. $num+=$params{skip};
  199. }
  200. @list = pagespec_match_list($params{page}, $params{pages},
  201. deptype => deptype($quick ? "presence" : "content"),
  202. filter => sub { $_[0] eq $params{page} },
  203. sort => exists $params{sort} ? $params{sort} : "age",
  204. reverse => yesno($params{reverse}),
  205. ($num ? (num => $num) : ()),
  206. );
  207. }
  208. if (exists $params{skip}) {
  209. @list=@list[$params{skip} .. $#list];
  210. }
  211. my @feedlist;
  212. if ($feeds) {
  213. if (exists $params{feedshow} &&
  214. $params{feedshow} && @list > $params{feedshow}) {
  215. @feedlist=@list[0..$params{feedshow} - 1];
  216. }
  217. else {
  218. @feedlist=@list;
  219. }
  220. }
  221. if ($params{show} && @list > $params{show}) {
  222. @list=@list[0..$params{show} - 1];
  223. }
  224. if ($feeds && exists $params{feedpages}) {
  225. @feedlist = pagespec_match_list(
  226. $params{page}, "($params{pages}) and ($params{feedpages})",
  227. deptype => deptype($quick ? "presence" : "content"),
  228. list => \@feedlist,
  229. );
  230. }
  231. my ($feedbase, $feednum);
  232. if ($feeds) {
  233. # Ensure that multiple feeds on a page go to unique files.
  234. # Feedfile can lead to conflicts if usedirs is not enabled,
  235. # so avoid supporting it in that case.
  236. delete $params{feedfile} if ! $config{usedirs};
  237. # Tight limits on legal feedfiles, to avoid security issues
  238. # and conflicts.
  239. if (defined $params{feedfile}) {
  240. if ($params{feedfile} =~ /\// ||
  241. $params{feedfile} !~ /$config{wiki_file_regexp}/) {
  242. error("illegal feedfile");
  243. }
  244. $params{feedfile}=possibly_foolish_untaint($params{feedfile});
  245. }
  246. $feedbase=targetpage($params{destpage}, "", $params{feedfile});
  247. my $feedid=join("\0", $feedbase, map { $_."\0".$params{$_} } sort keys %params);
  248. if (exists $knownfeeds{$feedid}) {
  249. $feednum=$knownfeeds{$feedid};
  250. }
  251. else {
  252. if (exists $page_numfeeds{$params{destpage}}{$feedbase}) {
  253. if ($feeds) {
  254. $feednum=$knownfeeds{$feedid}=++$page_numfeeds{$params{destpage}}{$feedbase};
  255. }
  256. }
  257. else {
  258. $feednum=$knownfeeds{$feedid}="";
  259. if ($feeds) {
  260. $page_numfeeds{$params{destpage}}{$feedbase}=1;
  261. }
  262. }
  263. }
  264. }
  265. my $rssurl=abs2rel($feedbase."rss".$feednum, dirname(htmlpage($params{destpage}))) if $feeds && $rss;
  266. my $atomurl=abs2rel($feedbase."atom".$feednum, dirname(htmlpage($params{destpage}))) if $feeds && $atom;
  267. my $ret="";
  268. if (length $config{cgiurl} && ! $params{preview} && (exists $params{rootpage} ||
  269. (exists $params{postform} && yesno($params{postform}))) &&
  270. IkiWiki->can("cgi_editpage")) {
  271. # Add a blog post form, with feed buttons.
  272. my $formtemplate=template_depends("blogpost.tmpl", $params{page}, blind_cache => 1);
  273. $formtemplate->param(cgiurl => $config{cgiurl});
  274. $formtemplate->param(rootpage => rootpage(%params));
  275. $formtemplate->param(rssurl => $rssurl) if $feeds && $rss;
  276. $formtemplate->param(atomurl => $atomurl) if $feeds && $atom;
  277. if (exists $params{postformtext}) {
  278. $formtemplate->param(postformtext =>
  279. $params{postformtext});
  280. }
  281. else {
  282. $formtemplate->param(postformtext =>
  283. gettext("Add a new post titled:"));
  284. }
  285. $ret.=$formtemplate->output;
  286. # The post form includes the feed buttons, so
  287. # emptyfeeds cannot be hidden.
  288. $emptyfeeds=1;
  289. }
  290. elsif ($feeds && !$params{preview} && ($emptyfeeds || @feedlist)) {
  291. # Add feed buttons.
  292. my $linktemplate=template_depends("feedlink.tmpl", $params{page}, blind_cache => 1);
  293. $linktemplate->param(rssurl => $rssurl) if $rss;
  294. $linktemplate->param(atomurl => $atomurl) if $atom;
  295. $ret.=$linktemplate->output;
  296. }
  297. if (! $feedonly) {
  298. my $template;
  299. if (! $raw) {
  300. eval {
  301. $template=template_depends($params{template}.".tmpl", $params{page},
  302. blind_cache => 1);
  303. };
  304. if ($@ || ! $template) {
  305. error sprintf(gettext("nonexistant template %s.tmpl"), $params{template});
  306. }
  307. }
  308. my $needcontent=$raw || (!($archive && $quick) && $template->query(name => 'content'));
  309. foreach my $page (@list) {
  310. my $file = $pagesources{$page};
  311. my $type = pagetype($file);
  312. if (! $raw) {
  313. if ($needcontent) {
  314. # Get the content before populating the
  315. # template, since getting the content uses
  316. # the same template if inlines are nested.
  317. my $content=get_inline_content($page, $params{destpage});
  318. $template->param(content => $content);
  319. }
  320. $template->param(pageurl => urlto($page, $params{destpage}));
  321. $template->param(inlinepage => $page);
  322. $template->param(title => pagetitle(basename($page)));
  323. $template->param(ctime => displaytime($pagectime{$page}, $params{timeformat}));
  324. $template->param(mtime => displaytime($pagemtime{$page}, $params{timeformat}));
  325. $template->param(first => 1) if $page eq $list[0];
  326. $template->param(last => 1) if $page eq $list[$#list];
  327. if ($actions) {
  328. my $file = $pagesources{$page};
  329. my $type = pagetype($file);
  330. if ($config{discussion}) {
  331. if ($page !~ /.*\/\Q$config{discussionpage}\E$/i &&
  332. (length $config{cgiurl} ||
  333. exists $pagesources{$page."/".lc($config{discussionpage})})) {
  334. $template->param(have_actions => 1);
  335. $template->param(discussionlink =>
  336. htmllink($page,
  337. $params{destpage},
  338. $config{discussionpage},
  339. noimageinline => 1,
  340. forcesubpage => 1));
  341. }
  342. }
  343. if (length $config{cgiurl} &&
  344. defined $type &&
  345. IkiWiki->can("cgi_editpage")) {
  346. $template->param(have_actions => 1);
  347. $template->param(editurl => cgiurl(do => "edit", page => $page));
  348. }
  349. }
  350. run_hooks(pagetemplate => sub {
  351. shift->(page => $page, destpage => $params{destpage},
  352. template => $template,);
  353. });
  354. $ret.=$template->output;
  355. $template->clear_params;
  356. }
  357. else {
  358. if (defined $type) {
  359. $ret.="\n".
  360. linkify($page, $params{destpage},
  361. preprocess($page, $params{destpage},
  362. filter($page, $params{destpage},
  363. readfile(srcfile($file)))));
  364. }
  365. else {
  366. $ret.="\n".
  367. readfile(srcfile($file));
  368. }
  369. }
  370. }
  371. }
  372. if ($feeds && ($emptyfeeds || @feedlist)) {
  373. if ($rss) {
  374. my $rssp=$feedbase."rss".$feednum;
  375. will_render($params{destpage}, $rssp);
  376. if (! $params{preview}) {
  377. writefile($rssp, $config{destdir},
  378. genfeed("rss",
  379. $config{url}."/".$rssp, $desc, $params{guid}, $params{destpage}, @feedlist));
  380. $toping{$params{destpage}}=1 unless $config{rebuild};
  381. $feedlinks{$params{destpage}}.=qq{<link rel="alternate" type="application/rss+xml" title="$desc (RSS)" href="$rssurl" />};
  382. }
  383. }
  384. if ($atom) {
  385. my $atomp=$feedbase."atom".$feednum;
  386. will_render($params{destpage}, $atomp);
  387. if (! $params{preview}) {
  388. writefile($atomp, $config{destdir},
  389. genfeed("atom", $config{url}."/".$atomp, $desc, $params{guid}, $params{destpage}, @feedlist));
  390. $toping{$params{destpage}}=1 unless $config{rebuild};
  391. $feedlinks{$params{destpage}}.=qq{<link rel="alternate" type="application/atom+xml" title="$desc (Atom)" href="$atomurl" />};
  392. }
  393. }
  394. }
  395. clear_inline_content_cache();
  396. return $ret if $raw || $nested;
  397. push @inline, $ret;
  398. return "<div class=\"inline\" id=\"$#inline\"></div>\n\n";
  399. }
  400. sub pagetemplate_inline (@) {
  401. my %params=@_;
  402. my $page=$params{page};
  403. my $template=$params{template};
  404. $template->param(feedlinks => $feedlinks{$page})
  405. if exists $feedlinks{$page} && $template->query(name => "feedlinks");
  406. }
  407. {
  408. my %inline_content;
  409. my $cached_destpage="";
  410. sub get_inline_content ($$) {
  411. my $page=shift;
  412. my $destpage=shift;
  413. if (exists $inline_content{$page} && $cached_destpage eq $destpage) {
  414. return $inline_content{$page};
  415. }
  416. my $file=$pagesources{$page};
  417. my $type=pagetype($file);
  418. my $ret="";
  419. if (defined $type) {
  420. $nested++;
  421. $ret=htmlize($page, $destpage, $type,
  422. linkify($page, $destpage,
  423. preprocess($page, $destpage,
  424. filter($page, $destpage,
  425. readfile(srcfile($file))))));
  426. $nested--;
  427. }
  428. if ($cached_destpage ne $destpage) {
  429. clear_inline_content_cache();
  430. $cached_destpage=$destpage;
  431. }
  432. return $inline_content{$page}=$ret;
  433. }
  434. sub clear_inline_content_cache () {
  435. %inline_content=();
  436. }
  437. }
  438. sub date_822 ($) {
  439. my $time=shift;
  440. my $lc_time=POSIX::setlocale(&POSIX::LC_TIME);
  441. POSIX::setlocale(&POSIX::LC_TIME, "C");
  442. my $ret=POSIX::strftime("%a, %d %b %Y %H:%M:%S %z", localtime($time));
  443. POSIX::setlocale(&POSIX::LC_TIME, $lc_time);
  444. return $ret;
  445. }
  446. sub date_3339 ($) {
  447. my $time=shift;
  448. my $lc_time=POSIX::setlocale(&POSIX::LC_TIME);
  449. POSIX::setlocale(&POSIX::LC_TIME, "C");
  450. my $ret=POSIX::strftime("%Y-%m-%dT%H:%M:%SZ", gmtime($time));
  451. POSIX::setlocale(&POSIX::LC_TIME, $lc_time);
  452. return $ret;
  453. }
  454. sub absolute_urls ($$) {
  455. # sucky sub because rss sucks
  456. my $content=shift;
  457. my $baseurl=shift;
  458. my $url=$baseurl;
  459. $url=~s/[^\/]+$//;
  460. # what is the non path part of the url?
  461. my $top_uri = URI->new($url);
  462. $top_uri->path_query(""); # reset the path
  463. my $urltop = $top_uri->as_string;
  464. $content=~s/(<a(?:\s+(?:class|id)\s*="?\w+"?)?)\s+href=\s*"(#[^"]+)"/$1 href="$baseurl$2"/mig;
  465. # relative to another wiki page
  466. $content=~s/(<a(?:\s+(?:class|id)\s*="?\w+"?)?)\s+href=\s*"(?!\w+:)([^\/][^"]*)"/$1 href="$url$2"/mig;
  467. $content=~s/(<img(?:\s+(?:class|id|width|height)\s*="?\w+"?)*)\s+src=\s*"(?!\w+:)([^\/][^"]*)"/$1 src="$url$2"/mig;
  468. # relative to the top of the site
  469. $content=~s/(<a(?:\s+(?:class|id)\s*="?\w+"?)?)\s+href=\s*"(?!\w+:)(\/[^"]*)"/$1 href="$urltop$2"/mig;
  470. $content=~s/(<img(?:\s+(?:class|id|width|height)\s*="?\w+"?)*)\s+src=\s*"(?!\w+:)(\/[^"]*)"/$1 src="$urltop$2"/mig;
  471. return $content;
  472. }
  473. sub genfeed ($$$$$@) {
  474. my $feedtype=shift;
  475. my $feedurl=shift;
  476. my $feeddesc=shift;
  477. my $guid=shift;
  478. my $page=shift;
  479. my @pages=@_;
  480. my $url=URI->new(encode_utf8(urlto($page,"",1)));
  481. my $itemtemplate=template_depends($feedtype."item.tmpl", $page, blind_cache => 1);
  482. my $content="";
  483. my $lasttime = 0;
  484. foreach my $p (@pages) {
  485. my $u=URI->new(encode_utf8(urlto($p, "", 1)));
  486. my $pcontent = absolute_urls(get_inline_content($p, $page), $url);
  487. $itemtemplate->param(
  488. title => pagetitle(basename($p)),
  489. url => $u,
  490. permalink => $u,
  491. cdate_822 => date_822($pagectime{$p}),
  492. mdate_822 => date_822($pagemtime{$p}),
  493. cdate_3339 => date_3339($pagectime{$p}),
  494. mdate_3339 => date_3339($pagemtime{$p}),
  495. );
  496. if (exists $pagestate{$p}) {
  497. if (exists $pagestate{$p}{meta}{guid}) {
  498. eval q{use HTML::Entities};
  499. $itemtemplate->param(guid => HTML::Entities::encode_numeric($pagestate{$p}{meta}{guid}));
  500. }
  501. if (exists $pagestate{$p}{meta}{updated}) {
  502. $itemtemplate->param(mdate_822 => date_822($pagestate{$p}{meta}{updated}));
  503. $itemtemplate->param(mdate_3339 => date_3339($pagestate{$p}{meta}{updated}));
  504. }
  505. }
  506. if ($itemtemplate->query(name => "enclosure")) {
  507. my $file=$pagesources{$p};
  508. my $type=pagetype($file);
  509. if (defined $type) {
  510. $itemtemplate->param(content => $pcontent);
  511. }
  512. else {
  513. my $size=(srcfile_stat($file))[8];
  514. my $mime="unknown";
  515. eval q{use File::MimeInfo};
  516. if (! $@) {
  517. $mime = mimetype($file);
  518. }
  519. $itemtemplate->param(
  520. enclosure => $u,
  521. type => $mime,
  522. length => $size,
  523. );
  524. }
  525. }
  526. else {
  527. $itemtemplate->param(content => $pcontent);
  528. }
  529. run_hooks(pagetemplate => sub {
  530. shift->(page => $p, destpage => $page,
  531. template => $itemtemplate);
  532. });
  533. $content.=$itemtemplate->output;
  534. $itemtemplate->clear_params;
  535. $lasttime = $pagemtime{$p} if $pagemtime{$p} > $lasttime;
  536. }
  537. my $template=template_depends($feedtype."page.tmpl", $page, blind_cache => 1);
  538. $template->param(
  539. title => $page ne "index" ? pagetitle($page) : $config{wikiname},
  540. wikiname => $config{wikiname},
  541. pageurl => $url,
  542. content => $content,
  543. feeddesc => $feeddesc,
  544. guid => $guid,
  545. feeddate => date_3339($lasttime),
  546. feedurl => $feedurl,
  547. version => $IkiWiki::version,
  548. );
  549. run_hooks(pagetemplate => sub {
  550. shift->(page => $page, destpage => $page,
  551. template => $template);
  552. });
  553. return $template->output;
  554. }
  555. sub pingurl (@) {
  556. return unless @{$config{pingurl}} && %toping;
  557. eval q{require RPC::XML::Client};
  558. if ($@) {
  559. debug(gettext("RPC::XML::Client not found, not pinging"));
  560. return;
  561. }
  562. # daemonize here so slow pings don't slow down wiki updates
  563. defined(my $pid = fork) or error("Can't fork: $!");
  564. return if $pid;
  565. chdir '/';
  566. POSIX::setsid() or error("Can't start a new session: $!");
  567. open STDIN, '/dev/null';
  568. open STDOUT, '>/dev/null';
  569. open STDERR, '>&STDOUT' or error("Can't dup stdout: $!");
  570. # Don't need to keep a lock on the wiki as a daemon.
  571. IkiWiki::unlockwiki();
  572. foreach my $page (keys %toping) {
  573. my $title=pagetitle(basename($page), 0);
  574. my $url=urlto($page, "", 1);
  575. foreach my $pingurl (@{$config{pingurl}}) {
  576. debug("Pinging $pingurl for $page");
  577. eval {
  578. my $client = RPC::XML::Client->new($pingurl);
  579. my $req = RPC::XML::request->new('weblogUpdates.ping',
  580. $title, $url);
  581. my $res = $client->send_request($req);
  582. if (! ref $res) {
  583. error("Did not receive response to ping");
  584. }
  585. my $r=$res->value;
  586. if (! exists $r->{flerror} || $r->{flerror}) {
  587. error("Ping rejected: ".(exists $r->{message} ? $r->{message} : "[unknown reason]"));
  588. }
  589. };
  590. if ($@) {
  591. error "Ping failed: $@";
  592. }
  593. }
  594. }
  595. exit 0; # daemon done
  596. }
  597. sub rootpage (@) {
  598. my %params=@_;
  599. my $rootpage;
  600. if (exists $params{rootpage}) {
  601. $rootpage=bestlink($params{page}, $params{rootpage});
  602. if (!length $rootpage) {
  603. $rootpage=$params{rootpage};
  604. }
  605. }
  606. else {
  607. $rootpage=$params{page};
  608. }
  609. return $rootpage;
  610. }
  611. 1