Merge commit 'intrigeri/po'

5 files changed, 990 insertions, 1 deletions

diff --git a/IkiWiki/Plugin/po.pm b/IkiWiki/Plugin/po.pm
new file mode 100644
index 000000000..9dda8c0db
--- /dev/null
+++ b/IkiWiki/Plugin/po.pm
@@ -0,0 +1,565 @@
+#!/usr/bin/perl
+# .po as a wiki page type
+# inspired by the GPL'd po4a-translate,
+# which is Copyright 2002, 2003, 2004 by Martin Quinson (mquinson#debian.org)
+package IkiWiki::Plugin::po;
+
+use warnings;
+use strict;
+use IkiWiki 2.00;
+use Encode;
+use Locale::Po4a::Chooser;
+use Locale::Po4a::Po;
+use File::Basename;
+use File::Copy;
+use File::Spec;
+use File::Temp;
+use Memoize;
+
+my %translations;
+our %filtered;
+
+## FIXME: makes some test cases cry once every two tries; this may be
+## related to the artificial way the testsuite is run, or not.
+# memoize("istranslatable");
+memoize("_istranslation");
+memoize("percenttranslated");
+
+# backup references to subs that will be overriden
+my %origsubs;
+$origsubs{'bestlink'}=\&IkiWiki::bestlink;
+$origsubs{'beautify_urlpath'}=\&IkiWiki::beautify_urlpath;
+$origsubs{'targetpage'}=\&IkiWiki::targetpage;
+
+sub import {
+	hook(type => "getsetup", id => "po", call => \&getsetup);
+	hook(type => "checkconfig", id => "po", call => \&checkconfig);
+	hook(type => "needsbuild", id => "po", call => \&needsbuild);
+	hook(type => "filter", id => "po", call => \&filter);
+	hook(type => "htmlize", id => "po", call => \&htmlize);
+	hook(type => "pagetemplate", id => "po", call => \&pagetemplate);
+	inject(name => "IkiWiki::bestlink", call => \&mybestlink);
+	inject(name => "IkiWiki::beautify_urlpath", call => \&mybeautify_urlpath);
+	inject(name => "IkiWiki::targetpage", call => \&mytargetpage);
+}
+
+sub getsetup () { #{{{
+	return
+		plugin => {
+			safe => 0,
+			rebuild => 1, # format plugin
+		},
+		po_master_language => {
+			type => "string",
+			example => {
+				'code' => 'en',
+				'name' => 'English'
+			},
+			description => "master language (non-PO files)",
+			safe => 0,
+			rebuild => 1,
+		},
+		po_slave_languages => {
+			type => "string",
+			example => {
+				'fr' => 'Français',
+				'es' => 'Castellano',
+				'de' => 'Deutsch'
+			},
+			description => "slave languages (PO files)",
+			safe => 0,
+			rebuild => 1,
+		},
+		po_translatable_pages => {
+			type => "pagespec",
+			example => "!*/Discussion",
+			description => "PageSpec controlling which pages are translatable",
+			link => "ikiwiki/PageSpec",
+			safe => 0,
+			rebuild => 1,
+		},
+		po_link_to => {
+			type => "string",
+			example => "current",
+			description => "internal linking behavior (default/current/negotiated)",
+			safe => 0,
+			rebuild => 1,
+		},
+} #}}}
+
+sub checkconfig () { #{{{
+	foreach my $field (qw{po_master_language po_slave_languages}) {
+		if (! exists $config{$field} || ! defined $config{$field}) {
+			error(sprintf(gettext("Must specify %s"), $field));
+		}
+	}
+	if (! exists $config{po_link_to} ||
+	    ! defined $config{po_link_to}) {
+	    $config{po_link_to}="default";
+	}
+	if (! exists $config{po_translatable_pages} ||
+	    ! defined $config{po_translatable_pages}) {
+	    $config{po_translatable_pages}="";
+	}
+	if ($config{po_link_to} eq "negotiated" && ! $config{usedirs}) {
+		error(gettext("po_link_to=negotiated requires usedirs to be set"));
+	}
+	push @{$config{wiki_file_prune_regexps}}, qr/\.pot$/;
+} #}}}
+
+sub potfile ($) { #{{{
+	my $masterfile=shift;
+	(my $name, my $dir, my $suffix) = fileparse($masterfile, qr/\.[^.]*/);
+	return File::Spec->catfile($dir, $name . ".pot");
+} #}}}
+
+sub pofile ($$) { #{{{
+	my $masterfile=shift;
+	my $lang=shift;
+	(my $name, my $dir, my $suffix) = fileparse($masterfile, qr/\.[^.]*/);
+	return File::Spec->catfile($dir, $name . "." . $lang . ".po");
+} #}}}
+
+sub refreshpot ($) { #{{{
+	my $masterfile=shift;
+	my $potfile=potfile($masterfile);
+	my %options = ("markdown" => (pagetype($masterfile) eq 'mdwn') ? 1 : 0);
+	my $doc=Locale::Po4a::Chooser::new('text',%options);
+	$doc->read($masterfile);
+	$doc->{TT}{utf_mode} = 1;
+	$doc->{TT}{file_in_charset} = 'utf-8';
+	$doc->{TT}{file_out_charset} = 'utf-8';
+	# let's cheat a bit to force porefs option to be passed to Locale::Po4a::Po;
+	# this is undocument use of internal Locale::Po4a::TransTractor's data,
+	# compulsory since this module prevents us from using the porefs option.
+	my %po_options = ('porefs' => 'none');
+	$doc->{TT}{po_out}=Locale::Po4a::Po->new(\%po_options);
+	$doc->{TT}{po_out}->set_charset('utf-8');
+	# do the actual work
+	$doc->parse;
+	$doc->writepo($potfile);
+} #}}}
+
+sub refreshpofiles ($@) { #{{{
+	my $masterfile=shift;
+	my @pofiles=@_;
+
+	my $potfile=potfile($masterfile);
+	error("[po/refreshpofiles] POT file ($potfile) does not exist") unless (-e $potfile);
+
+	foreach my $pofile (@pofiles) {
+		if (-e $pofile) {
+			my $cmd = "msgmerge -U --backup=none $pofile $potfile";
+			system ($cmd) == 0
+				or error("[po/refreshpofiles:$pofile] failed to update");
+		}
+		else {
+			File::Copy::syscopy($potfile,$pofile)
+				or error("[po/refreshpofiles:$pofile] failed to copy the POT file");
+		}
+	}
+} #}}}
+
+sub needsbuild () { #{{{
+	my $needsbuild=shift;
+
+	# build %translations, using istranslation's side-effect
+	foreach my $page (keys %pagesources) {
+		istranslation($page);
+	}
+
+	# refresh/create POT and PO files as needed
+	my $updated_po_files=0;
+	foreach my $page (keys %pagesources) {
+		my $pageneedsbuild = grep { $_ eq $pagesources{$page} } @$needsbuild;
+		if (istranslatable($page)) {
+			my $file=srcfile($pagesources{$page});
+			if ($pageneedsbuild || ! -e potfile($file)) {
+				refreshpot($file);
+			}
+			my @pofiles;
+			foreach my $lang (keys %{$config{po_slave_languages}}) {
+				my $pofile=pofile($file, $lang);
+				if ($pageneedsbuild || ! -e $pofile) {
+					push @pofiles, $pofile;
+				}
+			}
+			if (@pofiles) {
+				refreshpofiles($file, @pofiles) ;
+				map { IkiWiki::rcs_add($_); } @pofiles if ($config{rcs});
+				$updated_po_files = 1;
+			}
+		}
+	}
+
+	# check staged changes in and trigger a wiki refresh.
+	if ($updated_po_files) {
+		if ($config{rcs}) {
+			IkiWiki::disable_commit_hook();
+			IkiWiki::rcs_commit_staged(gettext("updated PO files"),
+				"refreshpofiles", "127.0.0.1");
+			IkiWiki::enable_commit_hook();
+			IkiWiki::rcs_update();
+		}
+		IkiWiki::refresh();
+		IkiWiki::saveindex();
+		# refresh module's private variables
+		undef %filtered;
+		undef %translations;
+		foreach my $page (keys %pagesources) {
+			istranslation($page);
+		}
+	}
+
+
+	# make existing translations depend on the corresponding master page
+	foreach my $master (keys %translations) {
+		foreach my $slave (values %{$translations{$master}}) {
+			add_depends($slave, $master);
+		}
+	}
+} #}}}
+
+sub mytargetpage ($$) { #{{{
+	my $page=shift;
+	my $ext=shift;
+
+	if (istranslation($page)) {
+		my ($masterpage, $lang) = ($page =~ /(.*)[.]([a-z]{2})$/);
+		if (! $config{usedirs} || $masterpage eq 'index') {
+			return $masterpage . "." . $lang . "." . $ext;
+		}
+		else {
+			return $masterpage . "/index." . $lang . "." . $ext;
+		}
+	}
+	elsif (istranslatable($page)) {
+		if (! $config{usedirs} || $page eq 'index') {
+			return $page . "." . $config{po_master_language}{code} . "." . $ext;
+		}
+		else {
+			return $page . "/index." . $config{po_master_language}{code} . "." . $ext;
+		}
+	}
+	return $origsubs{'targetpage'}->($page, $ext);
+} #}}}
+
+sub mybeautify_urlpath ($) { #{{{
+	my $url=shift;
+	my $res=$origsubs{'beautify_urlpath'}->($url);
+	if ($config{po_link_to} eq "negotiated") {
+		$res =~ s!/index.$config{po_master_language}{code}.$config{htmlext}$!/!;
+	}
+	return $res;
+} #}}}
+
+sub urlto_with_orig_beautiful_urlpath($$) { #{{{
+	my $to=shift;
+	my $from=shift;
+
+	inject(name => "IkiWiki::beautify_urlpath", call => $origsubs{'beautify_urlpath'});
+	my $res=urlto($to, $from);
+	inject(name => "IkiWiki::beautify_urlpath", call => \&mybeautify_urlpath);
+
+	return $res;
+} #}}}
+
+sub mybestlink ($$) { #{{{
+	my $page=shift;
+	my $link=shift;
+	my $res=$origsubs{'bestlink'}->($page, $link);
+	if (length $res) {
+		if ($config{po_link_to} eq "current"
+		    && istranslatable($res)
+		    && istranslation($page)) {
+			my ($masterpage, $curlang) = ($page =~ /(.*)[.]([a-z]{2})$/);
+			return $res . "." . $curlang;
+		}
+		else {
+			return $res;
+		}
+	}
+	return "";
+} #}}}
+
+# We use filter to convert PO to the master page's type,
+# since other plugins should not work on PO files
+sub filter (@) { #{{{
+	my %params = @_;
+	my $page = $params{page};
+	my $destpage = $params{destpage};
+	my $content = decode_utf8(encode_utf8($params{content}));
+
+	# decide if this is a PO file that should be converted into a translated document,
+	# and perform various sanity checks
+	if (! istranslation($page) || $filtered{$page}{$destpage}) {
+		return $content;
+	}
+
+	my ($masterpage, $lang) = ($page =~ /(.*)[.]([a-z]{2})$/);
+	my $file=srcfile(exists $params{file} ? $params{file} : $IkiWiki::pagesources{$page});
+	my $masterfile = srcfile($pagesources{$masterpage});
+	my (@pos,@masters);
+	push @pos,$file;
+	push @masters,$masterfile;
+	my %options = (
+			"markdown" => (pagetype($masterfile) eq 'mdwn') ? 1 : 0,
+			);
+	my $doc=Locale::Po4a::Chooser::new('text',%options);
+	$doc->process(
+		'po_in_name'	=> \@pos,
+		'file_in_name'	=> \@masters,
+		'file_in_charset'  => 'utf-8',
+		'file_out_charset' => 'utf-8',
+	) or error("[po/filter:$file]: failed to translate");
+	my $tmpfh = File::Temp->new(TEMPLATE => "/tmp/ikiwiki-po-filter-out.XXXXXXXXXX");
+	my $tmpout = $tmpfh->filename;
+	$doc->write($tmpout) or error("[po/filter:$file] could not write $tmpout");
+	$content = readfile($tmpout) or error("[po/filter:$file] could not read $tmpout");
+	$filtered{$page}{$destpage}=1;
+	return $content;
+} #}}}
+
+sub htmlize (@) { #{{{
+	my %params=@_;
+	my $page = $params{page};
+	my $content = $params{content};
+	my ($masterpage, $lang) = ($page =~ /(.*)[.]([a-z]{2})$/);
+	my $masterfile = srcfile($pagesources{$masterpage});
+
+	# force content to be htmlize'd as if it was the same type as the master page
+	return IkiWiki::htmlize($page, $page, pagetype($masterfile), $content);
+} #}}}
+
+sub percenttranslated ($) { #{{{
+	my $page=shift;
+	return "N/A" unless (istranslation($page));
+	my ($masterpage, $lang) = ($page =~ /(.*)[.]([a-z]{2})$/);
+	my $file=srcfile($pagesources{$page});
+	my $masterfile = srcfile($pagesources{$masterpage});
+	my (@pos,@masters);
+	push @pos,$file;
+	push @masters,$masterfile;
+	my %options = (
+			"markdown" => (pagetype($masterfile) eq 'mdwn') ? 1 : 0,
+			);
+	my $doc=Locale::Po4a::Chooser::new('text',%options);
+	$doc->process(
+		'po_in_name'	=> \@pos,
+		'file_in_name'	=> \@masters,
+		'file_in_charset'  => 'utf-8',
+		'file_out_charset' => 'utf-8',
+	) or error("[po/percenttranslated:$file]: failed to translate");
+	my ($percent,$hit,$queries) = $doc->stats();
+	return $percent;
+} #}}}
+
+sub otherlanguages ($) { #{{{
+	my $page=shift;
+	my @ret;
+	if (istranslatable($page)) {
+		foreach my $lang (sort keys %{$translations{$page}}) {
+			my $translation = $translations{$page}{$lang};
+			push @ret, {
+				url => urlto($translation, $page),
+				code => $lang,
+				language => $config{po_slave_languages}{$lang},
+				percent => percenttranslated($translation),
+			};
+		}
+	}
+	elsif (istranslation($page)) {
+		my ($masterpage, $curlang) = ($page =~ /(.*)[.]([a-z]{2})$/);
+		push @ret, {
+			url => urlto_with_orig_beautiful_urlpath($masterpage, $page),
+			code => $config{po_master_language}{code},
+			language => $config{po_master_language}{name},
+			master => 1,
+		};
+		foreach my $lang (sort keys %{$translations{$masterpage}}) {
+			push @ret, {
+				url => urlto($translations{$masterpage}{$lang}, $page),
+				code => $lang,
+				language => $config{po_slave_languages}{$lang},
+				percent => percenttranslated($translations{$masterpage}{$lang}),
+			} unless ($lang eq $curlang);
+		}
+	}
+	return @ret;
+} #}}}
+
+sub pagetemplate (@) { #{{{
+	my %params=@_;
+        my $page=$params{page};
+        my $destpage=$params{destpage};
+        my $template=$params{template};
+
+	if (istranslation($page) && $template->query(name => "percenttranslated")) {
+		$template->param(percenttranslated => percenttranslated($page));
+	}
+	if ($template->query(name => "istranslation")) {
+		$template->param(istranslation => istranslation($page));
+	}
+	if ($template->query(name => "istranslatable")) {
+		$template->param(istranslatable => istranslatable($page));
+	}
+	if ($template->query(name => "otherlanguages")) {
+		$template->param(otherlanguages => [otherlanguages($page)]);
+		if (istranslatable($page)) {
+			foreach my $translation (values %{$translations{$page}}) {
+				add_depends($page, $translation);
+			}
+		}
+		elsif (istranslation($page)) {
+			my ($masterpage, $curlang) = ($page =~ /(.*)[.]([a-z]{2})$/);
+			add_depends($page, $masterpage);
+			foreach my $translation (values %{$translations{$masterpage}}) {
+				add_depends($page, $translation);
+			}
+		}
+	}
+	# Rely on IkiWiki::Render's genpage() to decide wether
+	# a discussion link should appear on $page; this is not
+	# totally accurate, though: some broken links may be generated
+	# when cgiurl is disabled.
+	# This compromise avoids some code duplication, and will probably
+	# prevent future breakage when ikiwiki internals change.
+	# Known limitations are preferred to future random bugs.
+	if ($template->param('discussionlink') && istranslation($page)) {
+		my ($masterpage, $lang) = ($page =~ /(.*)[.]([a-z]{2})$/);
+		$template->param('discussionlink' => htmllink(
+							$page,
+							$destpage,
+							$masterpage . '/' . gettext("Discussion"),
+							noimageinline => 1,
+							forcesubpage => 0,
+							linktext => gettext("Discussion"),
+							));
+	}
+} # }}}
+
+sub istranslatable ($) { #{{{
+	my $page=shift;
+	my $file=$pagesources{$page};
+
+	if (! defined $file
+	    || (defined pagetype($file) && pagetype($file) eq 'po')
+	    || $file =~ /\.pot$/) {
+		return 0;
+	}
+	return pagespec_match($page, $config{po_translatable_pages});
+} #}}}
+
+sub _istranslation ($) { #{{{
+	my $page=shift;
+	my $file=$pagesources{$page};
+	if (! defined $file) {
+		return IkiWiki::FailReason->new("no file specified");
+	}
+
+	if (! defined $file
+	    || ! defined pagetype($file)
+ 	    || ! pagetype($file) eq 'po'
+	    || $file =~ /\.pot$/) {
+		return 0;
+	}
+
+	my ($masterpage, $lang) = ($page =~ /(.*)[.]([a-z]{2})$/);
+	if (! defined $masterpage || ! defined $lang
+	    || ! (length($masterpage) > 0) || ! (length($lang) > 0)
+	    || ! defined $pagesources{$masterpage}
+	    || ! defined $config{po_slave_languages}{$lang}) {
+		return 0;
+	}
+
+	return istranslatable($masterpage);
+} #}}}
+
+sub istranslation ($) { #{{{
+	my $page=shift;
+	if (_istranslation($page)) {
+		my ($masterpage, $lang) = ($page =~ /(.*)[.]([a-z]{2})$/);
+		$translations{$masterpage}{$lang}=$page unless exists $translations{$masterpage}{$lang};
+		return 1;
+	}
+	return 0;
+} #}}}
+
+package IkiWiki::PageSpec;
+use warnings;
+use strict;
+use IkiWiki 2.00;
+
+sub match_istranslation ($;@) { #{{{
+	my $page=shift;
+	if (IkiWiki::Plugin::po::istranslation($page)) {
+		return IkiWiki::SuccessReason->new("is a translation page");
+	}
+	else {
+		return IkiWiki::FailReason->new("is not a translation page");
+	}
+} #}}}
+
+sub match_istranslatable ($;@) { #{{{
+	my $page=shift;
+	if (IkiWiki::Plugin::po::istranslatable($page)) {
+		return IkiWiki::SuccessReason->new("is set as translatable in po_translatable_pages");
+	}
+	else {
+		return IkiWiki::FailReason->new("is not set as translatable in po_translatable_pages");
+	}
+} #}}}
+
+sub match_lang ($$;@) { #{{{
+	my $page=shift;
+	my $wanted=shift;
+	my $regexp=IkiWiki::glob2re($wanted);
+	my $lang;
+	my $masterpage;
+
+	if (IkiWiki::Plugin::po::istranslation($page)) {
+		($masterpage, $lang) = ($page =~ /(.*)[.]([a-z]{2})$/);
+	}
+	else {
+		$lang = $config{po_master_language}{code};
+	}
+
+	if ($lang!~/^$regexp$/i) {
+		return IkiWiki::FailReason->new("file language is $lang, not $wanted");
+	}
+	else {
+		return IkiWiki::SuccessReason->new("file language is $wanted");
+	}
+} #}}}
+
+sub match_currentlang ($$;@) { #{{{
+	my $page=shift;
+	shift;
+	my %params=@_;
+	my ($currentmasterpage, $currentlang, $masterpage, $lang);
+
+	return IkiWiki::FailReason->new("no location provided") unless exists $params{location};
+
+	if (IkiWiki::Plugin::po::istranslation($params{location})) {
+		($currentmasterpage, $currentlang) = ($params{location} =~ /(.*)[.]([a-z]{2})$/);
+	}
+	else {
+		$currentlang = $config{po_master_language}{code};
+	}
+
+	if (IkiWiki::Plugin::po::istranslation($page)) {
+		($masterpage, $lang) = ($page =~ /(.*)[.]([a-z]{2})$/);
+	}
+	else {
+		$lang = $config{po_master_language}{code};
+	}
+
+	if ($lang eq $currentlang) {
+		return IkiWiki::SuccessReason->new("file language is the same as current one, i.e. $currentlang");
+	}
+	else {
+		return IkiWiki::FailReason->new("file language is $lang, whereas current language is $currentlang");
+	}
+} #}}}
+
+1
diff --git a/doc/ikiwiki/pagespec/po.mdwn b/doc/ikiwiki/pagespec/po.mdwn
new file mode 100644
index 000000000..2edfaa0c1
--- /dev/null
+++ b/doc/ikiwiki/pagespec/po.mdwn
@@ -0,0 +1,16 @@
+[[!if test="enabled(po)"
+     then="This wiki has po support **enabled**."
+     else="This wiki has po support **disabled**."]]
+
+If the [[po|plugins/po]] plugin is enabled, the regular
+[[ikiwiki/PageSpec]] syntax is expanded with the following additional
+tests that can be used to improve user navigation in a multi-lingual
+wiki:
+
+* "`lang(LL)`" - Tests whether a page is written in the language
+  specified as a ISO639-1 (two-letter) language code.
+* "`currentlang()`" - Tests whether a page is written in the same
+  language as the current page.
+
+Note: every non-PO page is considered to be written in
+`po_master_language`, as specified in `ikiwiki.setup`.
diff --git a/doc/plugins/po.mdwn b/doc/plugins/po.mdwn
new file mode 100644
index 000000000..fe6b6b562
--- /dev/null
+++ b/doc/plugins/po.mdwn
@@ -0,0 +1,297 @@
+[[!template id=plugin name=po core=0 author="[[intrigeri]]"]]
+[[!tag type/format]]
+
+This plugin adds support for multi-lingual wikis, translated with
+gettext, using [po4a](http://po4a.alioth.debian.org/).
+
+It depends on the Perl `Locale::Po4a::Po` library (`apt-get install po4a`).
+
+Introduction
+============
+
+A language is chosen as the "master" one, and any other supported
+language is a "slave" one.
+
+A page written in the "master" language is a "master" page. It can be
+of any page type supported by ikiwiki, but PO. It does not have to be
+named a special way: migration to this plugin does not imply any page
+renaming work.
+
+Example: `bla/page.mdwn` is a "master" Markdown page written in
+English; if `usedirs` is enabled, it is rendered as
+`bla/page/index.en.html`, else as `bla/page.en.html`.
+
+Any translation of a "master" page into a "slave" language is called
+a "slave" page; it is written in the gettext PO format. PO is now
+a page type supported by ikiwiki.
+
+Example: `bla/page.fr.po` is the PO "message catalog" used to
+translate `bla/page.mdwn` into French; if `usedirs` is enabled, it is
+rendered as `bla/page/index.fr.html`, else as `bla/page.fr.html`
+
+
+Configuration
+=============
+
+Supported languages
+-------------------
+
+`po_master_language` is used to set the "master" language in
+`ikiwiki.setup`, such as:
+
+        po_master_language => { 'code' => 'en', 'name' => 'English' }
+
+`po_slave_languages` is used to set the list of supported "slave"
+languages, such as:
+
+        po_slave_languages => { 'fr' => 'Français',
+                                'es' => 'Castellano',
+                                'de' => 'Deutsch',
+        }
+
+Decide which pages are translatable
+-----------------------------------
+
+The `po_translatable_pages` setting configures what pages are
+translatable. It is a [[ikiwiki/PageSpec]], so you have lots of
+control over what kind of pages are translatable.
+
+The PO translations files are anyway not considered as being
+translatable, so you don't need to worry about excluding them
+explicitly from this [[ikiwiki/PageSpec]].
+
+Internal links
+--------------
+
+The `po_link_to` option in `ikiwiki.setup` is used to decide how
+internal links should be generated, depending on web server features
+and site-specific preferences.
+
+### Default linking behavior
+
+If `po_link_to` is unset, or set to `default`, ikiwiki's default
+linking behavior is preserved: `\[[destpage]]` links to the master
+language's page.
+
+### Link to current language
+
+If `po_link_to` is set to `current`, `\[[destpage]]` links to the
+`destpage`'s version written in the current page's language, if
+available, *i.e.*:
+
+- `foo/destpage/index.LL.html` if `usedirs` is enabled
+- `foo/destpage.LL.html` if `usedirs` is disabled
+
+### Link to negotiated language
+
+If `po_link_to` is set to `negotiated`, `\[[page]]` links to the
+negotiated preferred language, *i.e.* `foo/page/`.
+
+(In)compatibility notes:
+
+- if `usedirs` is disabled, it does not make sense to set `po_link_to`
+  to `negotiated`; this option combination is neither implemented
+  nor allowed.
+- if the web server does not support Content Negotiation, setting
+  `po_link_to` to `negotiated` will produce a unusable website.
+
+
+Server support
+==============
+
+Apache
+------
+
+Using Apache `mod_negotiation` makes it really easy to have Apache
+serve any page in the client's preferred language, if available.
+This is the default Debian Apache configuration.
+
+When `usedirs` is enabled, one has to set `DirectoryIndex index` for
+the wiki context.
+
+Setting `DefaultLanguage LL` (replace `LL` with your default MIME
+language code) for the wiki context can help to ensure
+`bla/page/index.en.html` is served as `Content-Language: LL`.
+
+lighttpd
+--------
+
+lighttpd unfortunately does not support content negotiation.
+
+**FIXME**: does `mod_magnet` provide the functionality needed to
+ emulate this?
+
+
+Usage
+=====
+
+Templates
+---------
+
+The `ISTRANSLATION` and `ISTRANSLATABLE` variables can be used to
+display things only on translatable or translation pages.
+
+### Display page's versions in other languages
+
+The `OTHERLANGUAGES` loop provides ways to display other languages'
+versions of the same page, and the translations' status.
+
+One typically adds the following code to `templates/page.tmpl`:
+
+	<TMPL_IF NAME="OTHERLANGUAGES">
+	<div id="otherlanguages">
+	  <ul>
+	  <TMPL_LOOP NAME="OTHERLANGUAGES">
+	    <li>
+	      <a href="<TMPL_VAR NAME="URL">"><TMPL_VAR NAME="LANGUAGE"></a>
+	      <TMPL_UNLESS NAME="MASTER">
+	        (<TMPL_VAR NAME="PERCENT">&nbsp;%)
+	      </TMPL_UNLESS>
+	    </li>
+	  </TMPL_LOOP>
+	  </ul>
+	</div>
+	</TMPL_IF>
+
+The following variables are available inside the loop (for every page in):
+
+- `URL` - url to the page
+- `CODE` - two-letters language code
+- `LANGUAGE` - language name (as defined in `po_slave_languages`)
+- `MASTER` - is true (1) if, and only if the page is a "master" page
+- `PERCENT` - for "slave" pages, is set to the translation completeness, in percents
+
+### Display the current translation status
+
+The `PERCENTTRANSLATED` variable is set to the translation
+completeness, expressed in percent, on "slave" pages.
+
+One can use it this way:
+
+	<TMPL_IF NAME="ISTRANSLATION">
+	<div id="percenttranslated">
+	  <TMPL_VAR NAME="PERCENTTRANSLATED">
+	</div>
+	</TMPL_IF>
+
+Additional PageSpec tests
+-------------------------
+
+This plugin enhances the regular [[ikiwiki/PageSpec]] syntax with some
+additional tests that are documented [[here|ikiwiki/pagespec/po]].
+
+Automatic PO files update
+-------------------------
+
+Committing changes to a "master" page:
+
+1. updates the POT file and the PO files for the supported languages
+   (this is done in the `needsbuild` hook); the updated PO files are
+   then put under version control
+2. triggers a refresh of the corresponding HTML slave pages (this is
+   achieved by making any "slave" page dependent on the corresponding
+   "master" page, in the `needsbuild` hook)
+
+Also, when the plugin has just been enabled, or when a page has just
+been declared as being translatable, the needed POT and PO files are
+created, and the PO files are checked into version control.
+
+Discussion pages
+----------------
+
+Discussion should happen in the language in which the pages are written for
+real, *i.e.* the "master" one. If discussion pages are enabled, "slave" pages
+therefore link to the "master" page's discussion page.
+
+Translating
+-----------
+
+One can edit the PO files using ikiwiki's CGI (a message-by-message interface
+could also be implemented at some point).
+
+If [[tips/untrusted_git_push]] is setup, one can edit the PO files in her
+preferred `$EDITOR`, without needing to be online.
+
+TODO
+====
+
+OTHERLANGUAGES dependencies
+---------------------------
+
+Pages using `OTHERLANGUAGES` depend on any "master" and "slave" pages
+whose status is being displayed. It is supposed to trigger dependency
+loops, but no practical bugs were noticed yet.
+
+Should pages using the `OTHERLANGUAGES` template loop be declared as
+linking to the same page in other versions? To be rigorous, they
+should, but this may clutter the backlinks.
+
+Security checks
+---------------
+
+- `refreshpofiles` uses `system()`, whose args have to be checked more
+  thoroughly to prevent any security issue (command injection, etc.).
+- `refreshpofiles` and `refreshpot` create new files; this may need
+  some checks, e.g. using `IkiWiki::prep_writefile()`
+
+gettext/po4a rough corners
+--------------------------
+
+- fix infinite loop when synchronizing two ikiwiki (when checkouts
+  live in different directories): say bla.fr.po has been updated in
+  repo2; pulling repo2 from repo1 seems to trigger a PO update, that
+  changes bla.fr.po in repo1; then pushing repo1 to repo2 triggers
+  a PO update, that changes bla.fr.po in repo2; etc.; fixed in
+  `629968fc89bced6727981c0a1138072631751fee`?
+- new translations created in the web interface must get proper charset/encoding
+  gettext metadata, else the next automatic PO update removes any non-ascii
+  chars; possible solution: put such metadata into the Pot file, and let it
+  propagate; should be fixed in `773de05a7a1ee68d2bed173367cf5e716884945a`, time
+  will tell.
+
+Misc. improvements
+------------------
+
+### preview
+
+preview does not work for PO files.
+
+### automatic POT/PO update
+
+Use the `change` hook instead of `needsbuild`?
+
+### page titles
+
+Use nice page titles from meta plugin in links, as inline already does. This is
+actually a duplicate for
+[[bugs/pagetitle_function_does_not_respect_meta_titles]], which might be fixed
+by something like [[todo/using_meta_titles_for_parentlinks]].
+
+### websetup
+
+Which configuration settings are safe enough for websetup?
+
+### parentlinks
+
+When the wiki home page is translatable, the parentlinks plugin sets
+`./index.html` as its translations' single parent link. Ideally, the home page's
+translations should get no parent link at all, just like the version written in
+the master language.
+
+### backlinks
+
+If a given translatable `sourcepage.mdwn` links to \[[destpage]],
+`sourcepage.LL.po` also link to \[[destpage]], and the latter has the master
+page *and* all its translations listed in the backlinks.
+
+Translation quality assurance
+-----------------------------
+
+Modifying a PO file via the CGI must be forbidden if the new version
+is not a valid PO file. As a bonus, check that it provides a more
+complete translation than the existing one.
+
+A new `cansave` type of hook would be needed to implement this.
+
+Note: committing to the underlying repository is a way to bypass
+this check.
diff --git a/t/po.t b/t/po.t
new file mode 100755
index 000000000..232c98c81
--- /dev/null
+++ b/t/po.t
@@ -0,0 +1,111 @@
+#!/usr/bin/perl
+# -*- cperl-indent-level: 8; -*-
+use warnings;
+use strict;
+use File::Temp;
+
+BEGIN {
+	unless (eval { require Locale::Po4a::Chooser }) {
+		eval q{
+			use Test::More skip_all => "Locale::Po4a::Chooser::new is not available"
+		}
+	}
+	unless (eval { require Locale::Po4a::Po }) {
+		eval q{
+			use Test::More skip_all => "Locale::Po4a::Po::new is not available"
+		}
+	}
+}
+
+use Test::More tests => 34;
+
+BEGIN { use_ok("IkiWiki"); }
+
+my $msgprefix;
+
+### Init
+%config=IkiWiki::defaultconfig();
+$config{srcdir}=$config{destdir}="/dev/null";
+## will need this when more thorough tests are written
+# $config{srcdir} = "t/po/src";
+# $config{destdir} = File::Temp->newdir("ikiwiki-test-po.XXXXXXXXXX", TMPDIR => 1)->dirname;
+$config{po_master_language} = { code => 'en',
+				name => 'English'
+			      };
+$config{po_slave_languages} = {
+			       es => 'Castellano',
+			       fr => "Français"
+			      };
+$config{po_translatable_pages}='index or test1 or test2';
+$config{po_link_to}='negotiated';
+IkiWiki::loadplugins();
+IkiWiki::checkconfig();
+ok(IkiWiki::loadplugin('po'), "po plugin loaded");
+
+### seed %pagesources and %pagecase
+$pagesources{'index'}='index.mdwn';
+$pagesources{'index.fr'}='index.fr.po';
+$pagesources{'test1'}='test1.mdwn';
+$pagesources{'test1.fr'}='test1.fr.po';
+$pagesources{'test2'}='test2.mdwn';
+$pagesources{'test2.es'}='test2.es.po';
+$pagesources{'test2.fr'}='test2.fr.po';
+$pagesources{'test3'}='test3.mdwn';
+$pagesources{'test3.es'}='test3.es.mdwn';
+foreach my $page (keys %pagesources) {
+    $IkiWiki::pagecase{lc $page}=$page;
+}
+
+### istranslatable/istranslation
+# we run these tests twice because memoization attempts made them
+# succeed once every two tries...
+ok(IkiWiki::Plugin::po::istranslatable('index'), "index is translatable");
+ok(IkiWiki::Plugin::po::istranslatable('index'), "index is translatable");
+ok(! IkiWiki::Plugin::po::istranslatable('index.fr'), "index is not translatable");
+ok(! IkiWiki::Plugin::po::istranslatable('index.fr'), "index is not translatable");
+ok(! IkiWiki::Plugin::po::istranslation('index'), "index is not a translation");
+ok(! IkiWiki::Plugin::po::istranslation('index'), "index is not a translation");
+ok(IkiWiki::Plugin::po::istranslation('index.fr'), "index.fr is a translation");
+ok(IkiWiki::Plugin::po::istranslation('index.fr'), "index.fr is a translation");
+ok(IkiWiki::Plugin::po::istranslatable('test2'), "test2 is translatable");
+ok(IkiWiki::Plugin::po::istranslatable('test2'), "test2 is translatable");
+ok(! IkiWiki::Plugin::po::istranslation('test2'), "test2 is not a translation");
+ok(! IkiWiki::Plugin::po::istranslation('test2'), "test2 is not a translation");
+ok(! IkiWiki::Plugin::po::istranslatable('test3'), "test3 is not translatable");
+ok(! IkiWiki::Plugin::po::istranslatable('test3'), "test3 is not translatable");
+ok(! IkiWiki::Plugin::po::istranslation('test3'), "test3 is not a translation");
+ok(! IkiWiki::Plugin::po::istranslation('test3'), "test3 is not a translation");
+
+### targetpage
+$config{usedirs}=0;
+$msgprefix="targetpage (usedirs=0)";
+is(targetpage('test1', 'html'), 'test1.en.html', "$msgprefix test1");
+is(targetpage('test1.fr', 'html'), 'test1.fr.html', "$msgprefix test1.fr");
+$config{usedirs}=1;
+$msgprefix="targetpage (usedirs=1)";
+is(targetpage('index', 'html'), 'index.en.html', "$msgprefix index");
+is(targetpage('index.fr', 'html'), 'index.fr.html', "$msgprefix index.fr");
+is(targetpage('test1', 'html'), 'test1/index.en.html', "$msgprefix test1");
+is(targetpage('test1.fr', 'html'), 'test1/index.fr.html', "$msgprefix test1.fr");
+is(targetpage('test3', 'html'), 'test3/index.html', "$msgprefix test3 (non-translatable page)");
+is(targetpage('test3.es', 'html'), 'test3.es/index.html', "$msgprefix test3.es (non-translatable page)");
+
+### bestlink
+$config{po_link_to}='current';
+$msgprefix="bestlink (po_link_to=current)";
+is(bestlink('test1.fr', 'test2'), 'test2.fr', "$msgprefix test1.fr -> test2");
+is(bestlink('test1.fr', 'test2.es'), 'test2.es', "$msgprefix test1.fr -> test2.es");
+$config{po_link_to}='negotiated';
+$msgprefix="bestlink (po_link_to=negotiated)";
+is(bestlink('test1.fr', 'test2'), 'test2', "$msgprefix test1.fr -> test2");
+is(bestlink('test1.fr', 'test2.es'), 'test2.es', "$msgprefix test1.fr -> test2.es");
+
+### beautify_urlpath
+$config{po_link_to}='default';
+$msgprefix="beautify_urlpath (po_link_to=default)";
+is(IkiWiki::beautify_urlpath('test1/index.en.html'), './test1/index.en.html', "$msgprefix test1/index.en.html");
+is(IkiWiki::beautify_urlpath('test1/index.fr.html'), './test1/index.fr.html', "$msgprefix test1/index.fr.html");
+$config{po_link_to}='negotiated';
+$msgprefix="beautify_urlpath (po_link_to=negotiated)";
+is(IkiWiki::beautify_urlpath('test1/index.en.html'), './test1/', "$msgprefix test1/index.en.html");
+is(IkiWiki::beautify_urlpath('test1/index.fr.html'), './test1/index.fr.html', "$msgprefix test1/index.fr.html");
diff --git a/t/syntax.t b/t/syntax.t
index d09d17f7f..8c96d1d84 100755
--- a/t/syntax.t
+++ b/t/syntax.t
@@ -6,7 +6,7 @@ use Test::More;
 my @progs="ikiwiki.in";
 my @libs="IkiWiki.pm";
 # monotone, external, amazon_s3 skipped since they need perl modules
-push @libs, map { chomp; $_ } `find IkiWiki -type f -name \\*.pm | grep -v monotone.pm | grep -v external.pm | grep -v amazon_s3.pm`;
+push @libs, map { chomp; $_ } `find IkiWiki -type f -name \\*.pm | grep -v monotone.pm | grep -v external.pm | grep -v amazon_s3.pm | grep -v po.pm`;
 push @libs, 'IkiWiki/Plugin/skeleton.pm.example';
 
 plan(tests => (@progs + @libs));