summaryrefslogtreecommitdiff
path: root/perl/Locale/Po4a/Text.pm
blob: fad995a56bb9dddee07d2760315e4f39b7f6e62d (plain)
  1. #!/usr/bin/perl -w
  2. # Po4a::Text.pm
  3. #
  4. # extract and translate translatable strings from a text documents
  5. #
  6. # This program is free software; you can redistribute it and/or modify
  7. # it under the terms of the GNU General Public License as published by
  8. # the Free Software Foundation; either version 2 of the License, or
  9. # (at your option) any later version.
  10. #
  11. # This program is distributed in the hope that it will be useful,
  12. # but WITHOUT ANY WARRANTY; without even the implied warranty of
  13. # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  14. # GNU General Public License for more details.
  15. #
  16. # You should have received a copy of the GNU General Public License
  17. # along with this program; if not, write to the Free Software
  18. # Foundation, Inc.,
  19. # 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA
  20. #
  21. ########################################################################
  22. =head1 NAME
  23. Locale::Po4a::Text - Convert text documents from/to PO files
  24. =head1 DESCRIPTION
  25. The po4a (po for anything) project goal is to ease translations (and more
  26. interestingly, the maintenance of translations) using gettext tools on
  27. areas where they were not expected like documentation.
  28. Locale::Po4a::Text is a module to help the translation of text documents into
  29. other [human] languages.
  30. Paragraphs are splitted on empty lines (or lines containing only spaces or
  31. tabulations).
  32. If a paragraph contains a line starting by a space (or tabulation), this
  33. paragraph won't be rewrapped.
  34. =cut
  35. package Locale::Po4a::Text;
  36. use 5.006;
  37. use strict;
  38. use warnings;
  39. require Exporter;
  40. use vars qw(@ISA @EXPORT);
  41. @ISA = qw(Locale::Po4a::TransTractor);
  42. @EXPORT = qw();
  43. use Locale::Po4a::TransTractor;
  44. use Locale::Po4a::Common;
  45. =head1 OPTIONS ACCEPTED BY THIS MODULE
  46. These are this module's particular options:
  47. =over
  48. =item B<nobullet>
  49. Deactivate detection of bullets.
  50. By default, when a bullet is detected, the bullet paragraph is not considered
  51. as a verbatim paragraph (with the no-wrap flag in the PO file), but the module
  52. rewrap this paragraph in the generated PO file and in the translation.
  53. =cut
  54. my $bullets = 1;
  55. =item B<debianchangelog>
  56. Handle the header and footer of
  57. released versions, which only contain non translatable informations.
  58. =cut
  59. my $debianchangelog = 0;
  60. =item B<fortunes>
  61. Handle the fortunes format, which separate fortunes with a line which
  62. consists in '%' or '%%', and use '%%' as the beginning of a comment.
  63. =cut
  64. my $fortunes = 0;
  65. =item B<markdown>
  66. Handle some special markup in Markdown-formatted texts.
  67. =cut
  68. my $markdown = 0;
  69. sub initialize {
  70. my $self = shift;
  71. my %options = @_;
  72. $self->{options}{'nobullets'}='';
  73. if (defined $options{'nobullets'}) {
  74. $bullets = 0;
  75. }
  76. if (defined $options{'debianchangelog'}) {
  77. $debianchangelog=1;
  78. }
  79. if (defined $options{'fortunes'}) {
  80. $fortunes=1;
  81. }
  82. if (defined $options{'markdown'}) {
  83. $markdown=1;
  84. }
  85. }
  86. sub parse {
  87. my $self = shift;
  88. my ($line,$ref);
  89. my $paragraph="";
  90. my $wrapped_mode = 1;
  91. my $expect_header = 1;
  92. ($line,$ref)=$self->shiftline();
  93. my $file = $ref;
  94. $file =~ s/:[0-9]+$//;
  95. while (defined($line)) {
  96. $ref =~ m/^(.*):[0-9]+$/;
  97. if ($1 ne $file) {
  98. $file = $1;
  99. do_paragraph($self,$paragraph,$wrapped_mode);
  100. $paragraph="";
  101. }
  102. # TODO: preserve original line ends throughout the code instead
  103. chomp($line);
  104. $self->{ref}="$ref";
  105. if ($debianchangelog and
  106. $expect_header and
  107. $line =~ /^(\w[-+0-9a-z.]*)\ \(([^\(\) \t]+)\) # src, version
  108. \s+([-+0-9a-z.]+); # distribution
  109. \s*urgency\s*\=\s*(.*\S)\s*$/ix) { #
  110. do_paragraph($self,$paragraph,$wrapped_mode);
  111. $paragraph="";
  112. $self->pushline("$line\n");
  113. $expect_header=0;
  114. } elsif ($debianchangelog and
  115. $line =~ m/^ \-\- (.*) <(.*)> ((\w+\,\s*)?\d{1,2}\s+\w+\s+\d{4}\s+\d{1,2}:\d\d:\d\d\s+[-+]\d{4}(\s+\([^\\\(\)]\))?)$/) {
  116. # Found trailer
  117. do_paragraph($self,$paragraph,$wrapped_mode);
  118. $paragraph="";
  119. $self->pushline("$line\n");
  120. $expect_header=1;
  121. } elsif ($fortunes and
  122. $line =~ m/^%%?\s*$/) {
  123. # Found end of fortune
  124. do_paragraph($self,$paragraph,$wrapped_mode);
  125. # FIXME: test if this is still needed when always adding
  126. # newline in do_paragraph()
  127. $self->pushline("\n") unless ( $wrapped_mode == 0
  128. or $paragraph eq "");
  129. $paragraph="";
  130. $wrapped_mode = 1;
  131. $self->pushline("$line\n");
  132. } elsif ($line =~ /^\s*$/) {
  133. # Break paragraphs on lines containing only spaces
  134. do_paragraph($self,$paragraph,$wrapped_mode);
  135. $paragraph="";
  136. $wrapped_mode = 1;
  137. $self->pushline($line."\n");
  138. } elsif ( $line =~ /^=*$/
  139. or $line =~ /^_*$/
  140. or $line =~ /^-*$/) {
  141. $wrapped_mode = 0;
  142. $paragraph .= $line."\n";
  143. do_paragraph($self,$paragraph,$wrapped_mode);
  144. $paragraph="";
  145. $wrapped_mode = 1;
  146. } elsif ($markdown and
  147. ( $line =~ /^#/ # headline
  148. or $line =~ /^\s*\[\[\!\S[^\]]*\]\]\s*$/)) { # sole macro
  149. # Found Markdown markup that should be preserved as a single line
  150. do_paragraph($self,$paragraph,$wrapped_mode);
  151. $paragraph="$line\n";
  152. $wrapped_mode = 0;
  153. do_paragraph($self,$paragraph,$wrapped_mode);
  154. $wrapped_mode = 1;
  155. $paragraph="";
  156. } elsif ($markdown and
  157. ( $paragraph =~ m/^>/ # blockquote
  158. or $paragraph =~ m/[<>]/ # maybe html
  159. or $paragraph =~ m/^"""/ # textblock inside macro end
  160. or $paragraph =~ m/"""$/)) { # textblock inside macro begin
  161. # Found Markdown markup that might not survive wrapping
  162. $wrapped_mode = 0;
  163. $paragraph .= $line."\n";
  164. } else {
  165. if ($line =~ /^\s/) {
  166. # A line starting by a space indicates a non-wrap
  167. # paragraph
  168. $wrapped_mode = 0;
  169. }
  170. if ($fortunes) {
  171. $line =~ s/%%(.*)$//;
  172. }
  173. # TODO: comments
  174. $paragraph .= $line."\n";
  175. }
  176. # paragraphs starting by a bullet, or numbered
  177. # or paragraphs with a line containing many consecutive spaces
  178. # (more than 3)
  179. # are considered as verbatim paragraphs
  180. $wrapped_mode = 0 if ( $paragraph =~ m/^(\*|[0-9]+[.)] )/s
  181. or $paragraph =~ m/[ \t][ \t][ \t]/s);
  182. ($line,$ref)=$self->shiftline();
  183. }
  184. if (length $paragraph) {
  185. do_paragraph($self,$paragraph,$wrapped_mode);
  186. }
  187. }
  188. sub do_paragraph {
  189. my ($self, $paragraph, $wrap) = (shift, shift, shift);
  190. return if ($paragraph eq "");
  191. if ($bullets) {
  192. # Detect bullets
  193. # | * blah blah
  194. # |<spaces> blah
  195. # | ^-- aligned
  196. # <empty line>
  197. #
  198. # Other bullets supported:
  199. # - blah o blah + blah
  200. # 1. blah 1) blah (1) blah
  201. TEST_BULLET:
  202. if ($paragraph =~ m/^(\s*)((?:[-*o+]|([0-9]+[.\)])|\([0-9]+\))\s+)([^\n]*\n)(.*)$/s) {
  203. my $para = $5;
  204. my $bullet = $2;
  205. my $indent1 = $1;
  206. my $indent2 = "$1".(' ' x length $bullet);
  207. my $text = $4;
  208. while ($para !~ m/$indent2(?:[-*o+]|([0-9]+[.\)])|\([0-9]+\))\s+/
  209. and $para =~ s/^$indent2(\S[^\n]*\n)//s) {
  210. $text .= $1;
  211. }
  212. # TODO: detect if a line starts with the same bullet
  213. if ($text !~ m/\S[ \t][ \t][ \t]+\S/s) {
  214. my $bullet_regex = quotemeta($indent1.$bullet);
  215. $bullet_regex =~ s/[0-9]+/\\d\+/;
  216. if ($para eq '' or $para =~ m/^$bullet_regex\S/s) {
  217. my $trans = $self->translate($text,
  218. $self->{ref},
  219. "Bullet: '$indent1$bullet'",
  220. "wrap" => 1,
  221. "wrapcol" => - (length $indent2));
  222. $trans =~ s/^/$indent1$bullet/s;
  223. $trans =~ s/\n(.)/\n$indent2$1/sg;
  224. $self->pushline( $trans."\n" );
  225. if ($para eq '') {
  226. return;
  227. } else {
  228. # Another bullet
  229. $paragraph = $para;
  230. goto TEST_BULLET;
  231. }
  232. }
  233. }
  234. }
  235. }
  236. # TODO: detect indented paragraphs
  237. my $transfinal = $self->translate($paragraph,
  238. $self->{ref},
  239. "Plain text",
  240. "wrap" => $wrap);
  241. # TODO: preserve original line ends throughout the code instead
  242. chomp $transfinal;
  243. $transfinal .= "\n";
  244. $self->pushline( $transfinal );
  245. }
  246. 1;
  247. =head1 STATUS OF THIS MODULE
  248. Tested successfully on simple text files and NEWS.Debian files.
  249. =head1 AUTHORS
  250. Nicolas François <nicolas.francois@centraliens.net>
  251. =head1 COPYRIGHT AND LICENSE
  252. Copyright 2005-2008 by Nicolas FRANÇOIS <nicolas.francois@centraliens.net>.
  253. This program is free software; you may redistribute it and/or modify it
  254. under the terms of GPL (see the COPYING file).