From bf228acd0a17dc912e51fcaf84e2d6cfa1b465b3 Mon Sep 17 00:00:00 2001
From: joey <joey@0fa5a96a-9a0e-0410-b3b2-a0fd24251071>
Date: Sat, 2 Jun 2007 05:05:22 +0000
Subject: * Add test suite for preprocessor directive parsing.

---
 t/preprocess.t | 54 ++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 54 insertions(+)
 create mode 100755 t/preprocess.t

(limited to 't/preprocess.t')

diff --git a/t/preprocess.t b/t/preprocess.t
new file mode 100755
index 000000000..e1afa4a26
--- /dev/null
+++ b/t/preprocess.t
@@ -0,0 +1,54 @@
+#!/usr/bin/perl
+use warnings;
+use strict;
+use Test::More tests => 14;
+
+BEGIN { use_ok("IkiWiki"); }
+
+$IkiWiki::hooks{preprocess}{foo}{call}=sub {
+	my @bits;
+	while (@_) {
+		my $key=shift;
+		my $value=shift;
+		next if $key eq 'page' || $key eq 'destpage' || $key eq 'preview';
+		if (length $value) {
+			push @bits, "$key => $value";
+		}
+		else {
+			push @bits, $key;
+		}
+	}
+	return "foo(".join(", ", @bits).")";
+};
+
+is(IkiWiki::preprocess("foo", "foo", "[[foo]]", 0, 0), "[[foo]]", "not wikilink");
+is(IkiWiki::preprocess("foo", "foo", "[[foo ]]", 0, 0), "foo()", "simple");
+is(IkiWiki::preprocess("foo", "foo", "[[foo a=1]]", 0, 0), "foo(a => 1)");
+is(IkiWiki::preprocess("foo", "foo", "[[foo ]] then [[foo a=2]]", 0, 0),
+	"foo() then foo(a => 2)");
+is(IkiWiki::preprocess("foo", "foo", "[[foo b c \"d\"]]", 0, 0), "foo(b, c, d)");
+is(IkiWiki::preprocess("foo", "foo", "[[foo a=1 b c=1]]", 0, 0),
+	"foo(a => 1, b, c => 1)");
+is(IkiWiki::preprocess("foo", "foo", "[[foo a=1 a=2 a=3]]", 0, 0),
+	"foo(a => 1, a => 2, a => 3)", "dup item");
+is(IkiWiki::preprocess("foo", "foo", '[[foo a="[[bracketed]]" b=1]]', 0, 0),
+	"foo(a => [[bracketed]], b => 1)");
+my $multiline="here is my \"first\"
+!! [[multiline ]] !!
+string!";
+is(IkiWiki::preprocess("foo", "foo", '[[foo a="""'.$multiline.'"""]]', 0, 0),
+	"foo(a => $multiline)");
+is(IkiWiki::preprocess("foo", "foo", '[[foo """'.$multiline.'"""]]', 0, 0),
+	"foo($multiline)");
+is(IkiWiki::preprocess("foo", "foo", '[[foo a="""'.$multiline.'""" b="foo"]]', 0, 0),
+	"foo(a => $multiline, b => foo)");
+is(IkiWiki::preprocess("foo", "foo", '[[foo a="""'."\n".$multiline."\n".'""" b="foo"]]', 0, 0),
+	"foo(a => $multiline, b => foo)", "leading/trailing newline stripped");
+
+TODO: {
+	local $TODO = "nested strings not yet implemented";
+
+	$multiline='here is a string containing another [[foo val="""string""]]';
+	is(IkiWiki::preprocess("foo", "foo", '[[foo a="""'.$multiline.'"""]]', 0, 0),
+		"foo(a=> $multiline)", "nested multiline strings");
+}
-- 
cgit v1.2.3