summaryrefslogtreecommitdiff
path: root/IkiWiki
diff options
context:
space:
mode:
Diffstat (limited to 'IkiWiki')
-rw-r--r--IkiWiki/Plugin/editpage.pm28
-rw-r--r--IkiWiki/Plugin/google.pm2
-rw-r--r--IkiWiki/Plugin/link.pm4
-rw-r--r--IkiWiki/Plugin/parentlinks.pm2
-rw-r--r--IkiWiki/Plugin/po.pm1127
-rw-r--r--IkiWiki/Plugin/remove.pm20
-rw-r--r--IkiWiki/Plugin/rename.pm31
-rw-r--r--IkiWiki/Plugin/search.pm2
-rw-r--r--IkiWiki/Plugin/skeleton.pm.example26
-rw-r--r--IkiWiki/Render.pm4
10 files changed, 1235 insertions, 11 deletions
diff --git a/IkiWiki/Plugin/editpage.pm b/IkiWiki/Plugin/editpage.pm
index ed994306f..91d125a5c 100644
--- a/IkiWiki/Plugin/editpage.pm
+++ b/IkiWiki/Plugin/editpage.pm
@@ -81,6 +81,33 @@ sub check_canedit ($$$;$) {
return $canedit;
}
+sub check_cansave ($$$$) {
+ my $page=shift;
+ my $content=shift;
+ my $q=shift;
+ my $session=shift;
+
+ my $cansave;
+ run_hooks(cansave => sub {
+ return if defined $cansave;
+ my $ret=shift->($page, $content, $q, $session);
+ if (defined $ret) {
+ if ($ret eq "") {
+ $cansave=1;
+ }
+ elsif (ref $ret eq 'CODE') {
+ $ret->();
+ $cansave=0;
+ }
+ else {
+ error($ret);
+ $cansave=0;
+ }
+ }
+ });
+ return $cansave;
+}
+
sub cgi_editpage ($$) {
my $q=shift;
my $session=shift;
@@ -370,6 +397,7 @@ sub cgi_editpage ($$) {
}
my $content=$form->field('editcontent');
+ check_cansave($page, $content, $q, $session);
run_hooks(editcontent => sub {
$content=shift->(
content => $content,
diff --git a/IkiWiki/Plugin/google.pm b/IkiWiki/Plugin/google.pm
index 4bba5775c..71948a7e9 100644
--- a/IkiWiki/Plugin/google.pm
+++ b/IkiWiki/Plugin/google.pm
@@ -24,7 +24,7 @@ sub getsetup () {
sub checkconfig () {
if (! length $config{url}) {
- error(sprintf(gettext("Must specify %s when using the google search plugin"), "url"));
+ error(sprintf(gettext("Must specify %s when using the %s plugin"), "url", 'google search'));
}
my $uri=URI->new($config{url});
if (! $uri || ! defined $uri->host) {
diff --git a/IkiWiki/Plugin/link.pm b/IkiWiki/Plugin/link.pm
index b79273f96..48691d973 100644
--- a/IkiWiki/Plugin/link.pm
+++ b/IkiWiki/Plugin/link.pm
@@ -12,7 +12,7 @@ sub import {
hook(type => "checkconfig", id => "link", call => \&checkconfig);
hook(type => "linkify", id => "link", call => \&linkify);
hook(type => "scan", id => "link", call => \&scan);
- hook(type => "renamepage", id => "link", call => \&renamepage);
+ hook(type => "renamelink", id => "link", call => \&renamelink);
}
sub getsetup () {
@@ -90,7 +90,7 @@ sub scan (@) {
}
}
-sub renamepage (@) {
+sub renamelink (@) {
my %params=@_;
my $page=$params{page};
my $old=$params{oldpage};
diff --git a/IkiWiki/Plugin/parentlinks.pm b/IkiWiki/Plugin/parentlinks.pm
index ebf1d449a..1ee69cbff 100644
--- a/IkiWiki/Plugin/parentlinks.pm
+++ b/IkiWiki/Plugin/parentlinks.pm
@@ -36,7 +36,7 @@ sub parentlinks ($) {
$depth=$i;
$height=($pagedepth - $depth);
push @ret, {
- url => urlto($path, $page),
+ url => urlto(bestlink($page, $path), $page),
page => $title,
depth => $depth,
height => $height,
diff --git a/IkiWiki/Plugin/po.pm b/IkiWiki/Plugin/po.pm
new file mode 100644
index 000000000..a307e5d6b
--- /dev/null
+++ b/IkiWiki/Plugin/po.pm
@@ -0,0 +1,1127 @@
+#!/usr/bin/perl
+# .po as a wiki page type
+# Licensed under GPL v2 or greater
+# Copyright (C) 2008-2009 intrigeri <intrigeri@boum.org>
+# inspired by the GPL'd po4a-translate,
+# which is Copyright 2002, 2003, 2004 by Martin Quinson (mquinson#debian.org)
+package IkiWiki::Plugin::po;
+
+use warnings;
+use strict;
+use IkiWiki 3.00;
+use Encode;
+use Locale::Po4a::Chooser;
+use Locale::Po4a::Po;
+use File::Basename;
+use File::Copy;
+use File::Spec;
+use File::Temp;
+use Memoize;
+use UNIVERSAL;
+
+my %translations;
+my @origneedsbuild;
+my %origsubs;
+
+memoize("istranslatable");
+memoize("_istranslation");
+memoize("percenttranslated");
+
+sub import {
+ hook(type => "getsetup", id => "po", call => \&getsetup);
+ hook(type => "checkconfig", id => "po", call => \&checkconfig);
+ hook(type => "needsbuild", id => "po", call => \&needsbuild);
+ hook(type => "scan", id => "po", call => \&scan, last =>1);
+ hook(type => "filter", id => "po", call => \&filter);
+ hook(type => "htmlize", id => "po", call => \&htmlize);
+ hook(type => "pagetemplate", id => "po", call => \&pagetemplate, last => 1);
+ hook(type => "postscan", id => "po", call => \&postscan);
+ hook(type => "rename", id => "po", call => \&renamepages, first => 1);
+ hook(type => "delete", id => "po", call => \&mydelete);
+ hook(type => "change", id => "po", call => \&change);
+ hook(type => "cansave", id => "po", call => \&cansave);
+ hook(type => "canremove", id => "po", call => \&canremove);
+ hook(type => "canrename", id => "po", call => \&canrename);
+ hook(type => "editcontent", id => "po", call => \&editcontent);
+ hook(type => "formbuilder_setup", id => "po", call => \&formbuilder_setup, last => 1);
+ hook(type => "formbuilder", id => "po", call => \&formbuilder);
+
+ $origsubs{'bestlink'}=\&IkiWiki::bestlink;
+ inject(name => "IkiWiki::bestlink", call => \&mybestlink);
+ $origsubs{'beautify_urlpath'}=\&IkiWiki::beautify_urlpath;
+ inject(name => "IkiWiki::beautify_urlpath", call => \&mybeautify_urlpath);
+ $origsubs{'targetpage'}=\&IkiWiki::targetpage;
+ inject(name => "IkiWiki::targetpage", call => \&mytargetpage);
+ $origsubs{'urlto'}=\&IkiWiki::urlto;
+ inject(name => "IkiWiki::urlto", call => \&myurlto);
+ $origsubs{'nicepagetitle'}=\&IkiWiki::nicepagetitle;
+ inject(name => "IkiWiki::nicepagetitle", call => \&mynicepagetitle);
+}
+
+
+# ,----
+# | Table of contents
+# `----
+
+# 1. Hooks
+# 2. Injected functions
+# 3. Blackboxes for private data
+# 4. Helper functions
+# 5. PageSpec's
+
+
+# ,----
+# | Hooks
+# `----
+
+sub getsetup () {
+ return
+ plugin => {
+ safe => 0,
+ rebuild => 1,
+ },
+ po_master_language => {
+ type => "string",
+ example => {
+ 'code' => 'en',
+ 'name' => 'English'
+ },
+ description => "master language (non-PO files)",
+ safe => 1,
+ rebuild => 1,
+ },
+ po_slave_languages => {
+ type => "string",
+ example => {
+ 'fr' => 'Français',
+ 'es' => 'Castellano',
+ 'de' => 'Deutsch'
+ },
+ description => "slave languages (PO files)",
+ safe => 1,
+ rebuild => 1,
+ },
+ po_translatable_pages => {
+ type => "pagespec",
+ example => "!*/Discussion",
+ description => "PageSpec controlling which pages are translatable",
+ link => "ikiwiki/PageSpec",
+ safe => 1,
+ rebuild => 1,
+ },
+ po_link_to => {
+ type => "string",
+ example => "current",
+ description => "internal linking behavior (default/current/negotiated)",
+ safe => 1,
+ rebuild => 1,
+ },
+ po_translation_status_in_links => {
+ type => "boolean",
+ example => 1,
+ description => "display translation status in links to translations",
+ safe => 1,
+ rebuild => 1,
+ },
+}
+
+sub checkconfig () {
+ foreach my $field (qw{po_master_language po_slave_languages}) {
+ if (! exists $config{$field} || ! defined $config{$field}) {
+ error(sprintf(gettext("Must specify %s when using the %s plugin"),
+ $field, 'po'));
+ }
+ }
+ if (! (keys %{$config{po_slave_languages}})) {
+ error(gettext("At least one slave language must be defined ".
+ "in po_slave_languages when using the po plugin"));
+ }
+ map {
+ islanguagecode($_)
+ or error(sprintf(gettext("%s is not a valid language code"), $_));
+ } ($config{po_master_language}{code}, keys %{$config{po_slave_languages}});
+ if (! exists $config{po_translatable_pages} ||
+ ! defined $config{po_translatable_pages}) {
+ $config{po_translatable_pages}="";
+ }
+ if (! exists $config{po_link_to} ||
+ ! defined $config{po_link_to}) {
+ $config{po_link_to}='default';
+ }
+ elsif (! grep {
+ $config{po_link_to} eq $_
+ } ('default', 'current', 'negotiated')) {
+ warn(sprintf(gettext('%s is not a valid value for po_link_to, falling back to po_link_to=default'),
+ $config{po_link_to}));
+ $config{po_link_to}='default';
+ }
+ elsif ($config{po_link_to} eq "negotiated" && ! $config{usedirs}) {
+ warn(gettext('po_link_to=negotiated requires usedirs to be enabled, falling back to po_link_to=default'));
+ $config{po_link_to}='default';
+ }
+ if (! exists $config{po_translation_status_in_links} ||
+ ! defined $config{po_translation_status_in_links}) {
+ $config{po_translation_status_in_links}=1;
+ }
+ push @{$config{wiki_file_prune_regexps}}, qr/\.pot$/;
+}
+
+sub needsbuild () {
+ my $needsbuild=shift;
+
+ # backup @needsbuild content so that change() can know whether
+ # a given master page was rendered because its source file was changed
+ @origneedsbuild=(@$needsbuild);
+
+ flushmemoizecache();
+ buildtranslationscache();
+
+ # make existing translations depend on the corresponding master page
+ foreach my $master (keys %translations) {
+ map add_depends($_, $master), values %{otherlanguages($master)};
+ }
+}
+
+# Massage the recorded state of internal links so that:
+# - it matches the actually generated links, rather than the links as written
+# in the pages' source
+# - backlinks are consistent in all cases
+sub scan (@) {
+ my %params=@_;
+ my $page=$params{page};
+ my $content=$params{content};
+
+ return unless UNIVERSAL::can("IkiWiki::Plugin::link", "import");
+
+ if (istranslation($page)) {
+ foreach my $destpage (@{$links{$page}}) {
+ if (istranslatable($destpage)) {
+ # replace one occurence of $destpage in $links{$page}
+ # (we only want to replace the one that was added by
+ # IkiWiki::Plugin::link::scan, other occurences may be
+ # there for other reasons)
+ for (my $i=0; $i<@{$links{$page}}; $i++) {
+ if (@{$links{$page}}[$i] eq $destpage) {
+ @{$links{$page}}[$i] = $destpage . '.' . lang($page);
+ last;
+ }
+ }
+ }
+ }
+ }
+ elsif (! istranslatable($page) && ! istranslation($page)) {
+ foreach my $destpage (@{$links{$page}}) {
+ if (istranslatable($destpage)) {
+ # make sure any destpage's translations has
+ # $page in its backlinks
+ push @{$links{$page}},
+ values %{otherlanguages($destpage)};
+ }
+ }
+ }
+}
+
+# We use filter to convert PO to the master page's format,
+# since the rest of ikiwiki should not work on PO files.
+sub filter (@) {
+ my %params = @_;
+
+ my $page = $params{page};
+ my $destpage = $params{destpage};
+ my $content = $params{content};
+ if (istranslation($page) && ! alreadyfiltered($page, $destpage)) {
+ $content = po_to_markup($page, $content);
+ setalreadyfiltered($page, $destpage);
+ }
+ return $content;
+}
+
+sub htmlize (@) {
+ my %params=@_;
+
+ my $page = $params{page};
+ my $content = $params{content};
+
+ # ignore PO files this plugin did not create
+ return $content unless istranslation($page);
+
+ # force content to be htmlize'd as if it was the same type as the master page
+ return IkiWiki::htmlize($page, $page,
+ pagetype(srcfile($pagesources{masterpage($page)})),
+ $content);
+}
+
+sub pagetemplate (@) {
+ my %params=@_;
+ my $page=$params{page};
+ my $destpage=$params{destpage};
+ my $template=$params{template};
+
+ my ($masterpage, $lang) = istranslation($page);
+
+ if (istranslation($page) && $template->query(name => "percenttranslated")) {
+ $template->param(percenttranslated => percenttranslated($page));
+ }
+ if ($template->query(name => "istranslation")) {
+ $template->param(istranslation => scalar istranslation($page));
+ }
+ if ($template->query(name => "istranslatable")) {
+ $template->param(istranslatable => istranslatable($page));
+ }
+ if ($template->query(name => "HOMEPAGEURL")) {
+ $template->param(homepageurl => homepageurl($page));
+ }
+ if ($template->query(name => "otherlanguages")) {
+ $template->param(otherlanguages => [otherlanguagesloop($page)]);
+ map add_depends($page, $_), (values %{otherlanguages($page)});
+ }
+ # Rely on IkiWiki::Render's genpage() to decide wether
+ # a discussion link should appear on $page; this is not
+ # totally accurate, though: some broken links may be generated
+ # when cgiurl is disabled.
+ # This compromise avoids some code duplication, and will probably
+ # prevent future breakage when ikiwiki internals change.
+ # Known limitations are preferred to future random bugs.
+ if ($template->param('discussionlink') && istranslation($page)) {
+ $template->param('discussionlink' => htmllink(
+ $page,
+ $destpage,
+ $masterpage . '/' . gettext("Discussion"),
+ noimageinline => 1,
+ forcesubpage => 0,
+ linktext => gettext("Discussion"),
+ ));
+ }
+ # Remove broken parentlink to ./index.html on home page's translations.
+ # It works because this hook has the "last" parameter set, to ensure it
+ # runs after parentlinks' own pagetemplate hook.
+ if ($template->param('parentlinks')
+ && istranslation($page)
+ && $masterpage eq "index") {
+ $template->param('parentlinks' => []);
+ }
+} # }}}
+
+sub postscan (@) {
+ my %params = @_;
+ my $page = $params{page};
+
+ # backlinks involve back-dependencies, so that nicepagetitle effects,
+ # such as translation status displayed in links, are updated
+ use IkiWiki::Render;
+ map add_depends($page, $_), keys %{$IkiWiki::backlinks{$page}};
+}
+
+# Add the renamed page translations to the list of to-be-renamed pages.
+sub renamepages($$$) {
+ my ($torename, $cgi, $session) = (shift, shift, shift);
+
+ # copy the initial array, so that we can iterate on it AND
+ # modify it at the same time, without iterating on the items we
+ # pushed on it ourselves
+ my @torename=@{$torename};
+
+ # Save the page(s) the user asked to rename, so that our
+ # canrename hook can tell the difference between:
+ # - a translation being renamed as a consequence of its master page
+ # being renamed
+ # - a user trying to directly rename a translation
+ # This is why this hook has to be run first, before @torename is modified
+ # by other plugins.
+ $session->param(po_orig_torename => [ @torename ]);
+ IkiWiki::cgi_savesession($session);
+
+ foreach my $rename (@torename) {
+ next unless istranslatable($rename->{src});
+ my %otherpages=%{otherlanguages($rename->{src})};
+ while (my ($lang, $otherpage) = each %otherpages) {
+ push @{$torename}, {
+ src => $otherpage,
+ srcfile => $pagesources{$otherpage},
+ dest => otherlanguage($rename->{dest}, $lang),
+ destfile => $rename->{dest}.".".$lang.".po",
+ required => 0,
+ };
+ }
+ }
+}
+
+sub mydelete(@) {
+ my @deleted=@_;
+
+ map { deletetranslations($_) } grep istranslatablefile($_), @deleted;
+}
+
+sub change(@) {
+ my @rendered=@_;
+
+ my $updated_po_files=0;
+
+ # Refresh/create POT and PO files as needed.
+ foreach my $file (grep {istranslatablefile($_)} @rendered) {
+ my $page=pagename($file);
+ my $masterfile=srcfile($file);
+ my $updated_pot_file=0;
+ # Only refresh Pot file if it does not exist, or if
+ # $pagesources{$page} was changed: don't if only the HTML was
+ # refreshed, e.g. because of a dependency.
+ if ((grep { $_ eq $pagesources{$page} } @origneedsbuild)
+ || ! -e potfile($masterfile)) {
+ refreshpot($masterfile);
+ $updated_pot_file=1;
+ }
+ my @pofiles;
+ map {
+ push @pofiles, $_ if ($updated_pot_file || ! -e $_);
+ } (pofiles($masterfile));
+ if (@pofiles) {
+ refreshpofiles($masterfile, @pofiles);
+ map { IkiWiki::rcs_add($_) } @pofiles if $config{rcs};
+ $updated_po_files=1;
+ }
+ }
+
+ if ($updated_po_files) {
+ commit_and_refresh(
+ gettext("updated PO files"),
+ "IkiWiki::Plugin::po::change");
+ }
+}
+
+sub cansave ($$$$) {
+ my ($page, $content, $cgi, $session) = (shift, shift, shift, shift);
+
+ if (istranslation($page)) {
+ my $res = isvalidpo($content);
+ if ($res) {
+ return undef;
+ }
+ else {
+ return "$res";
+ }
+ }
+ return undef;
+}
+
+sub canremove ($$$) {
+ my ($page, $cgi, $session) = (shift, shift, shift);
+
+ if (istranslation($page)) {
+ return gettext("Can not remove a translation. Removing the master page, ".
+ "though, removes its translations as well.");
+ }
+ return undef;
+}
+
+sub canrename ($$@) {
+ my ($cgi, $session) = (shift, shift);
+ my %params = @_;
+
+ if (istranslation($params{src})) {
+ my $masterpage = masterpage($params{src});
+ # Tell the difference between:
+ # - a translation being renamed as a consequence of its master page
+ # being renamed, which is allowed
+ # - a user trying to directly rename a translation, which is forbidden
+ # by looking for the master page in the list of to-be-renamed pages we
+ # saved early in the renaming process.
+ my $orig_torename = $session->param("po_orig_torename");
+ unless (scalar grep { $_->{src} eq $masterpage } @{$orig_torename}) {
+ return gettext("Can not rename a translation. Renaming the master page, ".
+ "though, renames its translations as well.");
+ }
+ }
+ return undef;
+}
+
+# As we're previewing or saving a page, the content may have
+# changed, so tell the next filter() invocation it must not be lazy.
+sub editcontent () {
+ my %params=@_;
+
+ unsetalreadyfiltered($params{page}, $params{page});
+ return $params{content};
+}
+
+sub formbuilder_setup (@) {
+ my %params=@_;
+ my $form=$params{form};
+ my $q=$params{cgi};
+
+ return unless defined $form->field("do");
+
+ if ($form->field("do") eq "create") {
+ # Warn the user: new pages must be written in master language.
+ my $template=template("pocreatepage.tmpl");
+ $template->param(LANG => $config{po_master_language}{name});
+ $form->tmpl_param(message => $template->output);
+ }
+ elsif ($form->field("do") eq "edit") {
+ # Remove the rename/remove buttons on slave pages.
+ # This has to be done after the rename/remove plugins have added
+ # their buttons, which is why this hook must be run last.
+ # The canrename/canremove hooks already ensure this is forbidden
+ # at the backend level, so this is only UI sugar.
+ if (istranslation($form->field("page"))) {
+ map {
+ for (my $i = 0; $i < @{$params{buttons}}; $i++) {
+ if (@{$params{buttons}}[$i] eq $_) {
+ delete @{$params{buttons}}[$i];
+ last;
+ }
+ }
+ } qw(Rename Remove);
+ }
+ }
+}
+
+sub formbuilder (@) {
+ my %params=@_;
+ my $form=$params{form};
+ my $q=$params{cgi};
+
+ return unless defined $form->field("do");
+
+ # Do not allow to create pages of type po: they are automatically created.
+ # The main reason to do so is to bypass the "favor the type of linking page
+ # on page creation" logic, which is unsuitable when a broken link is clicked
+ # on a slave (PO) page.
+ # This cannot be done in the formbuilder_setup hook as the list of types is
+ # computed later.
+ if ($form->field("do") eq "create") {
+ for my $field ($form->field) {
+ next unless "$field" eq "type";
+ if ($field->type eq 'select') {
+ # remove po from the list of types
+ my @types = grep { $_ ne 'po' } $field->options;
+ $field->options(\@types) if scalar @types;
+ }
+ else {
+ # make sure the default value is not po;
+ # does this case actually happen?
+ debug "po(formbuilder) ".gettext("type field is not select - not implemented yet");
+ }
+ }
+ }
+}
+
+# ,----
+# | Injected functions
+# `----
+
+# Implement po_link_to 'current' and 'negotiated' settings.
+sub mybestlink ($$) {
+ my $page=shift;
+ my $link=shift;
+
+ my $res=$origsubs{'bestlink'}->(masterpage($page), $link);
+ if (length $res
+ && ($config{po_link_to} eq "current" || $config{po_link_to} eq "negotiated")
+ && istranslatable($res)
+ && istranslation($page)) {
+ return $res . "." . lang($page);
+ }
+ return $res;
+}
+
+sub mybeautify_urlpath ($) {
+ my $url=shift;
+
+ my $res=$origsubs{'beautify_urlpath'}->($url);
+ if ($config{po_link_to} eq "negotiated") {
+ $res =~ s!/\Qindex.$config{po_master_language}{code}.$config{htmlext}\E$!/!;
+ $res =~ s!/\Qindex.$config{htmlext}\E$!/!;
+ map {
+ $res =~ s!/\Qindex.$_.$config{htmlext}\E$!/!;
+ } (keys %{$config{po_slave_languages}});
+ }
+ return $res;
+}
+
+sub mytargetpage ($$) {
+ my $page=shift;
+ my $ext=shift;
+
+ if (istranslation($page) || istranslatable($page)) {
+ my ($masterpage, $lang) = (masterpage($page), lang($page));
+ if (! $config{usedirs} || $masterpage eq 'index') {
+ return $masterpage . "." . $lang . "." . $ext;
+ }
+ else {
+ return $masterpage . "/index." . $lang . "." . $ext;
+ }
+ }
+ return $origsubs{'targetpage'}->($page, $ext);
+}
+
+sub myurlto ($$;$) {
+ my $to=shift;
+ my $from=shift;
+ my $absolute=shift;
+
+ # workaround hard-coded /index.$config{htmlext} in IkiWiki::urlto()
+ if (! length $to
+ && $config{po_link_to} eq "current"
+ && istranslatable('index')) {
+ return IkiWiki::beautify_urlpath(IkiWiki::baseurl($from) . "index." . lang($from) . ".$config{htmlext}");
+ }
+ # avoid using our injected beautify_urlpath if run by cgi_editpage,
+ # so that one is redirected to the just-edited page rather than to the
+ # negociated translation; to prevent unnecessary fiddling with caller/inject,
+ # we only do so when our beautify_urlpath would actually do what we want to
+ # avoid, i.e. when po_link_to = negotiated
+ if ($config{po_link_to} eq "negotiated") {
+ my @caller = caller(1);
+ my $run_by_editpage = 0;
+ $run_by_editpage = 1 if (exists $caller[3] && defined $caller[3]
+ && $caller[3] eq "IkiWiki::cgi_editpage");
+ inject(name => "IkiWiki::beautify_urlpath", call => $origsubs{'beautify_urlpath'})
+ if $run_by_editpage;
+ my $res = $origsubs{'urlto'}->($to,$from,$absolute);
+ inject(name => "IkiWiki::beautify_urlpath", call => \&mybeautify_urlpath)
+ if $run_by_editpage;
+ return $res;
+ }
+ else {
+ return $origsubs{'urlto'}->($to,$from,$absolute)
+ }
+}
+
+sub mynicepagetitle ($;$) {
+ my ($page, $unescaped) = (shift, shift);
+
+ my $res = $origsubs{'nicepagetitle'}->($page, $unescaped);
+ return $res unless istranslation($page);
+ return $res unless $config{po_translation_status_in_links};
+ return $res.' ('.percenttranslated($page).'&nbsp;%)';
+}
+
+# ,----
+# | Blackboxes for private data
+# `----
+
+{
+ my %filtered;
+
+ sub alreadyfiltered($$) {
+ my $page=shift;
+ my $destpage=shift;
+
+ return ( exists $filtered{$page}{$destpage}
+ && $filtered{$page}{$destpage} eq 1 );
+ }
+
+ sub setalreadyfiltered($$) {
+ my $page=shift;
+ my $destpage=shift;
+
+ $filtered{$page}{$destpage}=1;
+ }
+
+ sub unsetalreadyfiltered($$) {
+ my $page=shift;
+ my $destpage=shift;
+
+ if (exists $filtered{$page}{$destpage}) {
+ delete $filtered{$page}{$destpage};
+ }
+ }
+
+ sub resetalreadyfiltered() {
+ undef %filtered;
+ }
+}
+
+# ,----
+# | Helper functions
+# `----
+
+sub maybe_add_leading_slash ($;$) {
+ my $str=shift;
+ my $add=shift;
+ $add=1 unless defined $add;
+ return '/' . $str if $add;
+ return $str;
+}
+
+sub istranslatablefile ($) {
+ my $file=shift;
+
+ return 0 unless defined $file;
+ return 0 if (defined pagetype($file) && pagetype($file) eq 'po');
+ return 0 if $file =~ /\.pot$/;
+ return 1 if pagespec_match(pagename($file), $config{po_translatable_pages});
+ return;
+}
+
+sub istranslatable ($) {
+ my $page=shift;
+
+ $page=~s#^/##;
+ return 1 if istranslatablefile($pagesources{$page});
+ return;
+}
+
+sub _istranslation ($) {
+ my $page=shift;
+
+ my $hasleadingslash = ($page=~s#^/##);
+ my $file=$pagesources{$page};
+ return 0 unless (defined $file
+ && defined pagetype($file)
+ && pagetype($file) eq 'po');
+ return 0 if $file =~ /\.pot$/;
+
+ my ($masterpage, $lang) = ($page =~ /(.*)[.]([a-z]{2})$/);
+ return 0 unless (defined $masterpage && defined $lang
+ && length $masterpage && length $lang
+ && defined $pagesources{$masterpage}
+ && defined $config{po_slave_languages}{$lang});
+
+ return (maybe_add_leading_slash($masterpage, $hasleadingslash), $lang)
+ if istranslatable($masterpage);
+}
+
+sub istranslation ($) {
+ my $page=shift;
+
+ if (1 < (my ($masterpage, $lang) = _istranslation($page))) {
+ my $hasleadingslash = ($masterpage=~s#^/##);
+ $translations{$masterpage}{$lang}=$page unless exists $translations{$masterpage}{$lang};
+ return (maybe_add_leading_slash($masterpage, $hasleadingslash), $lang);
+ }
+ return;
+}
+
+sub masterpage ($) {
+ my $page=shift;
+
+ if ( 1 < (my ($masterpage, $lang) = _istranslation($page))) {
+ return $masterpage;
+ }
+ return $page;
+}
+
+sub lang ($) {
+ my $page=shift;
+
+ if (1 < (my ($masterpage, $lang) = _istranslation($page))) {
+ return $lang;
+ }
+ return $config{po_master_language}{code};
+}
+
+sub islanguagecode ($) {
+ my $code=shift;
+
+ return ($code =~ /^[a-z]{2}$/);
+}
+
+sub otherlanguage ($$) {
+ my $page=shift;
+ my $code=shift;
+
+ return masterpage($page) if $code eq $config{po_master_language}{code};
+ return masterpage($page) . '.' . $code;
+}
+
+sub otherlanguages ($) {
+ my $page=shift;
+
+ my %ret;
+ return \%ret unless (istranslation($page) || istranslatable($page));
+ my $curlang=lang($page);
+ foreach my $lang
+ ($config{po_master_language}{code}, keys %{$config{po_slave_languages}}) {
+ next if $lang eq $curlang;
+ $ret{$lang}=otherlanguage($page, $lang);
+ }
+ return \%ret;
+}
+
+sub potfile ($) {
+ my $masterfile=shift;
+
+ (my $name, my $dir, my $suffix) = fileparse($masterfile, qr/\.[^.]*/);
+ $dir='' if $dir eq './';
+ return File::Spec->catpath('', $dir, $name . ".pot");
+}
+
+sub pofile ($$) {
+ my $masterfile=shift;
+ my $lang=shift;
+
+ (my $name, my $dir, my $suffix) = fileparse($masterfile, qr/\.[^.]*/);
+ $dir='' if $dir eq './';
+ return File::Spec->catpath('', $dir, $name . "." . $lang . ".po");
+}
+
+sub pofiles ($) {
+ my $masterfile=shift;
+
+ return map pofile($masterfile, $_), (keys %{$config{po_slave_languages}});
+}
+
+sub refreshpot ($) {
+ my $masterfile=shift;
+
+ my $potfile=potfile($masterfile);
+ my %options = ("markdown" => (pagetype($masterfile) eq 'mdwn') ? 1 : 0);
+ my $doc=Locale::Po4a::Chooser::new('text',%options);
+ $doc->{TT}{utf_mode} = 1;
+ $doc->{TT}{file_in_charset} = 'utf-8';
+ $doc->{TT}{file_out_charset} = 'utf-8';
+ $doc->read($masterfile);
+ # let's cheat a bit to force porefs option to be passed to Locale::Po4a::Po;
+ # this is undocument use of internal Locale::Po4a::TransTractor's data,
+ # compulsory since this module prevents us from using the porefs option.
+ $doc->{TT}{po_out}=Locale::Po4a::Po->new({ 'porefs' => 'none' });
+ $doc->{TT}{po_out}->set_charset('utf-8');
+ # do the actual work
+ $doc->parse;
+ IkiWiki::prep_writefile(basename($potfile),dirname($potfile));
+ $doc->writepo($potfile);
+}
+
+sub refreshpofiles ($@) {
+ my $masterfile=shift;
+ my @pofiles=@_;
+
+ my $potfile=potfile($masterfile);
+ (-e $potfile)
+ or error("po(refreshpofiles) ".sprintf(gettext("POT file (%s) does not exist"),
+ $potfile));
+
+ foreach my $pofile (@pofiles) {
+ IkiWiki::prep_writefile(basename($pofile),dirname($pofile));
+ if (-e $pofile) {
+ system("msgmerge", "-U", "--backup=none", $pofile, $potfile) == 0
+ or error("po(refreshpofiles) ".
+ sprintf(gettext("failed to update %s"),
+ $pofile));
+ }
+ else {
+ File::Copy::syscopy($potfile,$pofile)
+ or error("po(refreshpofiles) ".
+ sprintf(gettext("failed to copy the POT file to %s"),
+ $pofile));
+ }
+ }
+}
+
+sub buildtranslationscache() {
+ # use istranslation's side-effect
+ map istranslation($_), (keys %pagesources);
+}
+
+sub resettranslationscache() {
+ undef %translations;
+}
+
+sub flushmemoizecache() {
+ Memoize::flush_cache("istranslatable");
+ Memoize::flush_cache("_istranslation");
+ Memoize::flush_cache("percenttranslated");
+}
+
+sub urlto_with_orig_beautiful_urlpath($$) {
+ my $to=shift;
+ my $from=shift;
+
+ inject(name => "IkiWiki::beautify_urlpath", call => $origsubs{'beautify_urlpath'});
+ my $res=urlto($to, $from);
+ inject(name => "IkiWiki::beautify_urlpath", call => \&mybeautify_urlpath);
+
+ return $res;
+}
+
+sub percenttranslated ($) {
+ my $page=shift;
+
+ $page=~s/^\///;
+ return gettext("N/A") unless istranslation($page);
+ my $file=srcfile($pagesources{$page});
+ my $masterfile = srcfile($pagesources{masterpage($page)});
+ my %options = (
+ "markdown" => (pagetype($masterfile) eq 'mdwn') ? 1 : 0,
+ );
+ my $doc=Locale::Po4a::Chooser::new('text',%options);
+ $doc->process(
+ 'po_in_name' => [ $file ],
+ 'file_in_name' => [ $masterfile ],
+ 'file_in_charset' => 'utf-8',
+ 'file_out_charset' => 'utf-8',
+ ) or error("po(percenttranslated) ".
+ sprintf(gettext("failed to translate %s"), $page));
+ my ($percent,$hit,$queries) = $doc->stats();
+ $percent =~ s/\.[0-9]+$//;
+ return $percent;
+}
+
+sub languagename ($) {
+ my $code=shift;
+
+ return $config{po_master_language}{name}
+ if $code eq $config{po_master_language}{code};
+ return $config{po_slave_languages}{$code}
+ if defined $config{po_slave_languages}{$code};
+ return;
+}
+
+sub otherlanguagesloop ($) {
+ my $page=shift;
+
+ my @ret;
+ my %otherpages=%{otherlanguages($page)};
+ while (my ($lang, $otherpage) = each %otherpages) {
+ if (istranslation($page) && masterpage($page) eq $otherpage) {
+ push @ret, {
+ url => urlto_with_orig_beautiful_urlpath($otherpage, $page),
+ code => $lang,
+ language => languagename($lang),
+ master => 1,
+ };
+ }
+ else {
+ push @ret, {
+ url => urlto_with_orig_beautiful_urlpath($otherpage, $page),
+ code => $lang,
+ language => languagename($lang),
+ percent => percenttranslated($otherpage),
+ }
+ }
+ }
+ return sort {
+ return -1 if $a->{code} eq $config{po_master_language}{code};
+ return 1 if $b->{code} eq $config{po_master_language}{code};
+ return $a->{language} cmp $b->{language};
+ } @ret;
+}
+
+sub homepageurl (;$) {
+ my $page=shift;
+
+ return urlto('', $page);
+}
+
+sub deletetranslations ($) {
+ my $deletedmasterfile=shift;
+
+ my $deletedmasterpage=pagename($deletedmasterfile);
+ my @todelete;
+ map {
+ my $file = newpagefile($deletedmasterpage.'.'.$_, 'po');
+ my $absfile = "$config{srcdir}/$file";
+ if (-e $absfile && ! -l $absfile && ! -d $absfile) {
+ push @todelete, $file;
+ }
+ } keys %{$config{po_slave_languages}};
+
+ map {
+ if ($config{rcs}) {
+ IkiWiki::rcs_remove($_);
+ }
+ else {
+ IkiWiki::prune("$config{srcdir}/$_");
+ }
+ } @todelete;
+
+ if (scalar @todelete) {
+ commit_and_refresh(
+ gettext("removed obsolete PO files"),
+ "IkiWiki::Plugin::po::deletetranslations");
+ }
+}
+
+sub commit_and_refresh ($$) {
+ my ($msg, $author) = (shift, shift);
+
+ if ($config{rcs}) {
+ IkiWiki::disable_commit_hook();
+ IkiWiki::rcs_commit_staged($msg, $author, "127.0.0.1");
+ IkiWiki::enable_commit_hook();
+ IkiWiki::rcs_update();
+ }
+ # Reinitialize module's private variables.
+ resetalreadyfiltered();
+ resettranslationscache();
+ flushmemoizecache();
+ # Trigger a wiki refresh.
+ require IkiWiki::Render;
+ # without preliminary saveindex/loadindex, refresh()
+ # complains about a lot of uninitialized variables
+ IkiWiki::saveindex();
+ IkiWiki::loadindex();
+ IkiWiki::refresh();
+ IkiWiki::saveindex();
+}
+
+# on success, returns the filtered content.
+# on error, if $nonfatal, warn and return undef; else, error out.
+sub po_to_markup ($$;$) {
+ my ($page, $content) = (shift, shift);
+ my $nonfatal = shift;
+
+ $content = '' unless defined $content;
+ $content = decode_utf8(encode_utf8($content));
+ # CRLF line terminators make poor Locale::Po4a feel bad
+ $content=~s/\r\n/\n/g;
+
+ # There are incompatibilities between some File::Temp versions
+ # (including 0.18, bundled with Lenny's perl-modules package)
+ # and others (e.g. 0.20, previously present in the archive as
+ # a standalone package): under certain circumstances, some
+ # return a relative filename, whereas others return an absolute one;
+ # we here use this module in a way that is at least compatible
+ # with 0.18 and 0.20. Beware, hit'n'run refactorers!
+ my $infile = new File::Temp(TEMPLATE => "ikiwiki-po-filter-in.XXXXXXXXXX",
+ DIR => File::Spec->tmpdir,
+ UNLINK => 1)->filename;
+ my $outfile = new File::Temp(TEMPLATE => "ikiwiki-po-filter-out.XXXXXXXXXX",
+ DIR => File::Spec->tmpdir,
+ UNLINK => 1)->filename;
+
+ my $fail = sub ($) {
+ my $msg = "po(po_to_markup) - $page : " . shift;
+ if ($nonfatal) {
+ warn $msg;
+ return undef;
+ }
+ error($msg, sub { unlink $infile, $outfile});
+ };
+
+ writefile(basename($infile), File::Spec->tmpdir, $content)
+ or return $fail->(sprintf(gettext("failed to write %s"), $infile));
+
+ my $masterfile = srcfile($pagesources{masterpage($page)});
+ my %options = (
+ "markdown" => (pagetype($masterfile) eq 'mdwn') ? 1 : 0,
+ );
+ my $doc=Locale::Po4a::Chooser::new('text',%options);
+ $doc->process(
+ 'po_in_name' => [ $infile ],
+ 'file_in_name' => [ $masterfile ],
+ 'file_in_charset' => 'utf-8',
+ 'file_out_charset' => 'utf-8',
+ ) or return $fail->(gettext("failed to translate"));
+ $doc->write($outfile)
+ or return $fail->(sprintf(gettext("failed to write %s"), $outfile));
+
+ $content = readfile($outfile)
+ or return $fail->(sprintf(gettext("failed to read %s"), $outfile));
+
+ # Unlinking should happen automatically, thanks to File::Temp,
+ # but it does not work here, probably because of the way writefile()
+ # and Locale::Po4a::write() work.
+ unlink $infile, $outfile;
+
+ return $content;
+}
+
+# returns a SuccessReason or FailReason object
+sub isvalidpo ($) {
+ my $content = shift;
+
+ # NB: we don't use po_to_markup here, since Po4a parser does
+ # not mind invalid PO content
+ $content = '' unless defined $content;
+ $content = decode_utf8(encode_utf8($content));
+
+ # There are incompatibilities between some File::Temp versions
+ # (including 0.18, bundled with Lenny's perl-modules package)
+ # and others (e.g. 0.20, previously present in the archive as
+ # a standalone package): under certain circumstances, some
+ # return a relative filename, whereas others return an absolute one;
+ # we here use this module in a way that is at least compatible
+ # with 0.18 and 0.20. Beware, hit'n'run refactorers!
+ my $infile = new File::Temp(TEMPLATE => "ikiwiki-po-isvalidpo.XXXXXXXXXX",
+ DIR => File::Spec->tmpdir,
+ UNLINK => 1)->filename;
+
+ my $fail = sub ($) {
+ my $msg = '[po/isvalidpo] ' . shift;
+ unlink $infile;
+ return IkiWiki::FailReason->new("$msg");
+ };
+
+ writefile(basename($infile), File::Spec->tmpdir, $content)
+ or return $fail->(sprintf(gettext("failed to write %s"), $infile));
+
+ my $res = (system("msgfmt", "--check", $infile, "-o", "/dev/null") == 0);
+
+ # Unlinking should happen automatically, thanks to File::Temp,
+ # but it does not work here, probably because of the way writefile()
+ # and Locale::Po4a::write() work.
+ unlink $infile;
+
+ if ($res) {
+ return IkiWiki::SuccessReason->new("valid gettext data");
+ }
+ return IkiWiki::FailReason->new("invalid gettext data, go back ".
+ "to previous page to go on with edit");
+}
+
+# ,----
+# | PageSpec's
+# `----
+
+package IkiWiki::PageSpec;
+use warnings;
+use strict;
+use IkiWiki 2.00;
+
+sub match_istranslation ($;@) {
+ my $page=shift;
+
+ if (IkiWiki::Plugin::po::istranslation($page)) {
+ return IkiWiki::SuccessReason->new("is a translation page");
+ }
+ else {
+ return IkiWiki::FailReason->new("is not a translation page");
+ }
+}
+
+sub match_istranslatable ($;@) {
+ my $page=shift;
+
+ if (IkiWiki::Plugin::po::istranslatable($page)) {
+ return IkiWiki::SuccessReason->new("is set as translatable in po_translatable_pages");
+ }
+ else {
+ return IkiWiki::FailReason->new("is not set as translatable in po_translatable_pages");
+ }
+}
+
+sub match_lang ($$;@) {
+ my $page=shift;
+ my $wanted=shift;
+
+ my $regexp=IkiWiki::glob2re($wanted);
+ my $lang=IkiWiki::Plugin::po::lang($page);
+ if ($lang!~/^$regexp$/i) {
+ return IkiWiki::FailReason->new("file language is $lang, not $wanted");
+ }
+ else {
+ return IkiWiki::SuccessReason->new("file language is $wanted");
+ }
+}
+
+sub match_currentlang ($$;@) {
+ my $page=shift;
+ shift;
+ my %params=@_;
+
+ return IkiWiki::FailReason->new("no location provided") unless exists $params{location};
+
+ my $currentlang=IkiWiki::Plugin::po::lang($params{location});
+ my $lang=IkiWiki::Plugin::po::lang($page);
+
+ if ($lang eq $currentlang) {
+ return IkiWiki::SuccessReason->new("file language is the same as current one, i.e. $currentlang");
+ }
+ else {
+ return IkiWiki::FailReason->new("file language is $lang, whereas current language is $currentlang");
+ }
+}
+
+1
diff --git a/IkiWiki/Plugin/remove.pm b/IkiWiki/Plugin/remove.pm
index 21989aff3..2e3614cca 100644
--- a/IkiWiki/Plugin/remove.pm
+++ b/IkiWiki/Plugin/remove.pm
@@ -54,6 +54,26 @@ sub check_canremove ($$$) {
error("renaming of attachments is not allowed");
}
}
+
+ my $canremove;
+ IkiWiki::run_hooks(canremove => sub {
+ return if defined $canremove;
+ my $ret=shift->($page, $q, $session);
+ if (defined $ret) {
+ if ($ret eq "") {
+ $canremove=1;
+ }
+ elsif (ref $ret eq 'CODE') {
+ $ret->();
+ $canremove=0;
+ }
+ elsif (defined $ret) {
+ error($ret);
+ $canremove=0;
+ }
+ }
+ });
+ return $canremove;
}
sub formbuilder_setup (@) {
diff --git a/IkiWiki/Plugin/rename.pm b/IkiWiki/Plugin/rename.pm
index 41af3ca4d..f79349561 100644
--- a/IkiWiki/Plugin/rename.pm
+++ b/IkiWiki/Plugin/rename.pm
@@ -87,6 +87,27 @@ sub check_canrename ($$$$$$) {
IkiWiki::Plugin::attachment::check_canattach($session, $dest, $srcfile);
}
}
+
+ my $canrename;
+ IkiWiki::run_hooks(canrename => sub {
+ return if defined $canrename;
+ my $ret=shift->($q, $session, src => $src, srcfile => $srcfile,
+ dest => $dest, destfile => $destfile);
+ if (defined $ret) {
+ if ($ret eq "") {
+ $canrename=1;
+ }
+ elsif (ref $ret eq 'CODE') {
+ $ret->();
+ $canrename=0;
+ }
+ elsif (defined $ret) {
+ error($ret);
+ $canrename=0;
+ }
+ }
+ });
+ return $canrename;
}
sub rename_form ($$$) {
@@ -195,7 +216,7 @@ sub postrename ($;$$$) {
# Update edit form content to fix any links present
# on it.
$postrename->param("editcontent",
- renamepage_hook($dest, $src, $dest,
+ renamelink_hook($dest, $src, $dest,
$postrename->param("editcontent")));
# Get a new edit token; old was likely invalidated.
@@ -291,6 +312,8 @@ sub sessioncgi ($$) {
required => 1,
};
+ IkiWiki::run_hooks(rename => sub { shift->(\@torename, $q, $session); });
+
# See if any subpages need to be renamed.
if ($q->param("subpages") && $src ne $dest) {
foreach my $p (keys %pagesources) {
@@ -423,10 +446,10 @@ sub linklist {
} @{$list}]
}
-sub renamepage_hook ($$$$) {
+sub renamelink_hook ($$$$) {
my ($page, $src, $dest, $content)=@_;
- IkiWiki::run_hooks(renamepage => sub {
+ IkiWiki::run_hooks(renamelink => sub {
$content=shift->(
page => $page,
oldpage => $src,
@@ -483,7 +506,7 @@ sub fixlinks ($$$) {
if ($needfix) {
my $file=$pagesources{$page};
my $oldcontent=readfile($config{srcdir}."/".$file);
- my $content=renamepage_hook($page, $rename->{src}, $rename->{dest}, $oldcontent);
+ my $content=renamelink_hook($page, $rename->{src}, $rename->{dest}, $oldcontent);
if ($oldcontent ne $content) {
my $token=IkiWiki::rcs_prepedit($file);
eval { writefile($file, $config{srcdir}, $content) };
diff --git a/IkiWiki/Plugin/search.pm b/IkiWiki/Plugin/search.pm
index d79e3170e..393c17e0f 100644
--- a/IkiWiki/Plugin/search.pm
+++ b/IkiWiki/Plugin/search.pm
@@ -33,7 +33,7 @@ sub getsetup () {
sub checkconfig () {
foreach my $required (qw(url cgiurl)) {
if (! length $config{$required}) {
- error(sprintf(gettext("Must specify %s when using the search plugin"), $required));
+ error(sprintf(gettext("Must specify %s when using the %s plugin"), $required, 'search'));
}
}
diff --git a/IkiWiki/Plugin/skeleton.pm.example b/IkiWiki/Plugin/skeleton.pm.example
index 4d7b4e717..0bd5edeef 100644
--- a/IkiWiki/Plugin/skeleton.pm.example
+++ b/IkiWiki/Plugin/skeleton.pm.example
@@ -30,6 +30,7 @@ sub import {
hook(type => "auth", id => "skeleton", call => \&auth);
hook(type => "sessioncgi", id => "skeleton", call => \&sessioncgi);
hook(type => "canedit", id => "skeleton", call => \&canedit);
+ hook(type => "cansave", id => "skeleton", call => \&cansave);
hook(type => "editcontent", id => "skeleton", call => \&editcontent);
hook(type => "formbuilder_setup", id => "skeleton", call => \&formbuilder_setup);
hook(type => "formbuilder", id => "skeleton", call => \&formbuilder);
@@ -180,6 +181,31 @@ sub canedit ($$$) {
debug("skeleton plugin running in canedit");
}
+sub cansave ($$$$) {
+ my $page=shift;
+ my $content=shift;
+ my $cgi=shift;
+ my $session=shift;
+
+ debug("skeleton plugin running in cansave");
+}
+
+sub canremove ($$$) {
+ my $page=shift;
+ my $cgi=shift;
+ my $session=shift;
+
+ debug("skeleton plugin running in canremove");
+}
+
+sub canrename ($$$) {
+ my $page=shift;
+ my $cgi=shift;
+ my $session=shift;
+
+ debug("skeleton plugin running in canrename");
+}
+
sub editcontent ($$$) {
my %params=@_;
diff --git a/IkiWiki/Render.pm b/IkiWiki/Render.pm
index adae9f0d5..8e4c8af71 100644
--- a/IkiWiki/Render.pm
+++ b/IkiWiki/Render.pm
@@ -7,8 +7,8 @@ use strict;
use IkiWiki;
use Encode;
-my %backlinks;
-my $backlinks_calculated=0;
+our %backlinks=();
+our $backlinks_calculated=0;
sub calculate_backlinks () {
return if $backlinks_calculated;
generated by cgit v1.2.3 (git 2.46.0) at 2024-12-14 01:45:14 +0000