summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
Diffstat
-rw-r--r--IkiWiki.pm46
-rw-r--r--IkiWiki/Plugin/po.pm521
-rw-r--r--IkiWiki/Plugin/skeleton.pm.example10
-rw-r--r--doc/ikiwiki/pagespec/po.mdwn16
-rw-r--r--doc/plugins/po.mdwn300
-rw-r--r--doc/plugins/write.mdwn30
-rwxr-xr-xt/syntax.t2
7 files changed, 914 insertions, 11 deletions
diff --git a/IkiWiki.pm b/IkiWiki.pm
index 207ca87fb..67cd2147d 100644
--- a/IkiWiki.pm
+++ b/IkiWiki.pm
@@ -647,8 +647,19 @@ sub newpagefile ($$) { #{{{
sub targetpage ($$) { #{{{
my $page=shift;
my $ext=shift;
-
- if (! $config{usedirs} || $page eq 'index') {
+
+ my $targetpage='';
+ run_hooks(targetpage => sub {
+ $targetpage=shift->(
+ page => $page,
+ ext => $ext,
+ );
+ });
+
+ if (defined $targetpage && (length($targetpage) > 0)) {
+ return $targetpage;
+ }
+ elsif (! $config{usedirs} || $page eq 'index') {
return $page.".".$ext;
}
else {
@@ -796,6 +807,7 @@ sub will_render ($$;$) { #{{{
sub bestlink ($$) { #{{{
my $page=shift;
my $link=shift;
+ my $res=undef;
my $cwd=$page;
if ($link=~s/^\/+//) {
@@ -810,25 +822,35 @@ sub bestlink ($$) { #{{{
$l.=$link;
if (exists $links{$l}) {
- return $l;
+ $res=$l;
}
elsif (exists $pagecase{lc $l}) {
- return $pagecase{lc $l};
+ $res=$pagecase{lc $l};
}
- } while $cwd=~s{/?[^/]+$}{};
+ } while ($cwd=~s{/?[^/]+$}{} && ! defined $res);
- if (length $config{userdir}) {
+ if (! defined $res && length $config{userdir}) {
my $l = "$config{userdir}/".lc($link);
if (exists $links{$l}) {
- return $l;
+ $res=$l;
}
elsif (exists $pagecase{lc $l}) {
- return $pagecase{lc $l};
+ $res=$pagecase{lc $l};
}
}
- #print STDERR "warning: page $page, broken link: $link\n";
- return "";
+ if (defined $res) {
+ run_hooks(tweakbestlink => sub {
+ $res=shift->(
+ page => $page,
+ link => $res);
+ });
+ return $res;
+ }
+ else {
+ #print STDERR "warning: page $page, broken link: $link\n";
+ return "";
+ }
} #}}}
sub isinlinableimage ($) { #{{{
@@ -933,6 +955,10 @@ sub beautify_urlpath ($) { #{{{
$url =~ s!/index.$config{htmlext}$!/!;
}
+ run_hooks(tweakurlpath => sub {
+ $url=shift->(url => $url);
+ });
+
# Ensure url is not an empty link, and
# if it's relative, make that explicit to avoid colon confusion.
if ($url !~ /^\//) {
diff --git a/IkiWiki/Plugin/po.pm b/IkiWiki/Plugin/po.pm
new file mode 100644
index 000000000..f535ebd39
--- /dev/null
+++ b/IkiWiki/Plugin/po.pm
@@ -0,0 +1,521 @@
+#!/usr/bin/perl
+# .po as a wiki page type
+# inspired by the GPL'd po4a-translate,
+# which is Copyright 2002, 2003, 2004 by Martin Quinson (mquinson#debian.org)
+package IkiWiki::Plugin::po;
+
+use warnings;
+use strict;
+use IkiWiki 2.00;
+use Encode;
+use Locale::Po4a::Chooser;
+use Locale::Po4a::Po;
+use File::Basename;
+use File::Copy;
+use File::Spec;
+use File::Temp;
+use Memoize;
+
+my %translations;
+our %filtered;
+memoize("istranslatable");
+memoize("_istranslation");
+memoize("percenttranslated");
+
+sub import {
+ hook(type => "getsetup", id => "po", call => \&getsetup);
+ hook(type => "checkconfig", id => "po", call => \&checkconfig);
+ hook(type => "needsbuild", id => "po", call => \&needsbuild);
+ hook(type => "targetpage", id => "po", call => \&targetpage);
+ hook(type => "tweakurlpath", id => "po", call => \&tweakurlpath);
+ hook(type => "tweakbestlink", id => "po", call => \&tweakbestlink);
+ hook(type => "filter", id => "po", call => \&filter);
+ hook(type => "htmlize", id => "po", call => \&htmlize);
+ hook(type => "pagetemplate", id => "po", call => \&pagetemplate);
+}
+
+sub getsetup () { #{{{
+ return
+ plugin => {
+ safe => 0,
+ rebuild => 1, # format plugin
+ },
+ po_master_language => {
+ type => "string",
+ example => {
+ 'code' => 'en',
+ 'name' => 'English'
+ },
+ description => "master language (non-PO files)",
+ safe => 0,
+ rebuild => 1,
+ },
+ po_slave_languages => {
+ type => "string",
+ example => {
+ 'fr' => 'Français',
+ 'es' => 'Castellano',
+ 'de' => 'Deutsch'
+ },
+ description => "slave languages (PO files)",
+ safe => 0,
+ rebuild => 1,
+ },
+ po_translatable_pages => {
+ type => "pagespec",
+ example => "!*/Discussion",
+ description => "PageSpec controlling which pages are translatable",
+ link => "ikiwiki/PageSpec",
+ safe => 0,
+ rebuild => 1,
+ },
+ po_link_to => {
+ type => "string",
+ example => "current",
+ description => "internal linking behavior (default/current/negotiated)",
+ safe => 0,
+ rebuild => 1,
+ },
+} #}}}
+
+sub checkconfig () { #{{{
+ foreach my $field (qw{po_master_language po_slave_languages}) {
+ if (! exists $config{$field} || ! defined $config{$field}) {
+ error(sprintf(gettext("Must specify %s"), $field));
+ }
+ }
+ if (! exists $config{po_link_to} ||
+ ! defined $config{po_link_to}) {
+ $config{po_link_to}="default";
+ }
+ if (! exists $config{po_translatable_pages} ||
+ ! defined $config{po_translatable_pages}) {
+ $config{po_translatable_pages}="";
+ }
+ if ($config{po_link_to} eq "negotiated" && ! $config{usedirs}) {
+ error(gettext("po_link_to=negotiated requires usedirs to be set"));
+ }
+ push @{$config{wiki_file_prune_regexps}}, qr/\.pot$/;
+} #}}}
+
+sub potfile ($) { #{{{
+ my $masterfile=shift;
+ (my $name, my $dir, my $suffix) = fileparse($masterfile, qr/\.[^.]*/);
+ return File::Spec->catfile($dir, $name . ".pot");
+} #}}}
+
+sub pofile ($$) { #{{{
+ my $masterfile=shift;
+ my $lang=shift;
+ (my $name, my $dir, my $suffix) = fileparse($masterfile, qr/\.[^.]*/);
+ return File::Spec->catfile($dir, $name . "." . $lang . ".po");
+} #}}}
+
+sub refreshpot ($) { #{{{
+ my $masterfile=shift;
+ my $potfile=potfile($masterfile);
+ my %options = ("markdown" => (pagetype($masterfile) eq 'mdwn') ? 1 : 0);
+ my $doc=Locale::Po4a::Chooser::new('text',%options);
+ $doc->read($masterfile);
+ $doc->{TT}{utf_mode} = 1;
+ $doc->{TT}{file_in_charset} = 'utf-8';
+ $doc->{TT}{file_out_charset} = 'utf-8';
+ # let's cheat a bit to force porefs option to be passed to Locale::Po4a::Po;
+ # this is undocument use of internal Locale::Po4a::TransTractor's data,
+ # compulsory since this module prevents us from using the porefs option.
+ my %po_options = ('porefs' => 'none');
+ $doc->{TT}{po_out}=Locale::Po4a::Po->new(\%po_options);
+ # do the actual work
+ $doc->parse;
+ $doc->writepo($potfile);
+} #}}}
+
+sub refreshpofiles ($@) { #{{{
+ my $masterfile=shift;
+ my @pofiles=@_;
+
+ my $potfile=potfile($masterfile);
+ error("[po/refreshpofiles] POT file ($potfile) does not exist") unless (-e $potfile);
+
+ foreach my $pofile (@pofiles) {
+ if (-e $pofile) {
+ my $cmd = "msgmerge -U --backup=none $pofile $potfile";
+ system ($cmd) == 0
+ or error("[po/refreshpofiles:$pofile] failed to update");
+ }
+ else {
+ File::Copy::syscopy($potfile,$pofile)
+ or error("[po/refreshpofiles:$pofile] failed to copy the POT file");
+ }
+ }
+} #}}}
+
+sub needsbuild () { #{{{
+ my $needsbuild=shift;
+
+ # build %translations, using istranslation's side-effect
+ foreach my $page (keys %pagesources) {
+ istranslation($page);
+ }
+
+ # refresh/create POT and PO files as needed
+ my $updated_po_files=0;
+ foreach my $page (keys %pagesources) {
+ my $pageneedsbuild = grep { $_ eq $pagesources{$page} } @$needsbuild;
+ if (istranslatable($page)) {
+ my $file=srcfile($pagesources{$page});
+ if ($pageneedsbuild || ! -e potfile($file)) {
+ refreshpot($file);
+ }
+ my @pofiles;
+ foreach my $lang (keys %{$config{po_slave_languages}}) {
+ my $pofile=pofile($file, $lang);
+ if ($pageneedsbuild || ! -e $pofile) {
+ push @pofiles, $pofile;
+ }
+ }
+ if (@pofiles) {
+ refreshpofiles($file, @pofiles) ;
+ map { IkiWiki::rcs_add($_); } @pofiles if ($config{rcs});
+ $updated_po_files = 1;
+ }
+ }
+ }
+
+ # check staged changes in and trigger a wiki refresh.
+ if ($updated_po_files) {
+ if ($config{rcs}) {
+ IkiWiki::disable_commit_hook();
+ IkiWiki::rcs_commit_staged(gettext("updated PO files"),
+ "refreshpofiles", "127.0.0.1");
+ IkiWiki::enable_commit_hook();
+ IkiWiki::rcs_update();
+ }
+ IkiWiki::refresh();
+ IkiWiki::saveindex();
+ # refresh module's private variables
+ %filtered=undef;
+ %translations=undef;
+ foreach my $page (keys %pagesources) {
+ istranslation($page);
+ }
+ }
+
+
+ # make existing translations depend on the corresponding master page
+ foreach my $master (keys %translations) {
+ foreach my $slave (values %{$translations{$master}}) {
+ add_depends($slave, $master);
+ }
+ }
+} #}}}
+
+sub targetpage (@) { #{{{
+ my %params = @_;
+ my $page=$params{page};
+ my $ext=$params{ext};
+
+ if (istranslation($page)) {
+ my ($masterpage, $lang) = ($page =~ /(.*)[.]([a-z]{2})$/);
+ if (! $config{usedirs} || $page eq 'index') {
+ return $masterpage . "." . $lang . "." . $ext;
+ }
+ else {
+ return $masterpage . "/index." . $lang . "." . $ext;
+ }
+ }
+ elsif (istranslatable($page)) {
+ if (! $config{usedirs} || $page eq 'index') {
+ return $page . "." . $config{po_master_language}{code} . "." . $ext;
+ }
+ else {
+ return $page . "/index." . $config{po_master_language}{code} . "." . $ext;
+ }
+ }
+ return;
+} #}}}
+
+sub tweakurlpath ($) { #{{{
+ my %params = @_;
+ my $url=$params{url};
+ if ($config{po_link_to} eq "negotiated") {
+ $url =~ s!/index.$config{po_master_language}{code}.$config{htmlext}$!/!;
+ }
+ return $url;
+} #}}}
+
+sub tweakbestlink ($$) { #{{{
+ my %params = @_;
+ my $page=$params{page};
+ my $link=$params{link};
+ if ($config{po_link_to} eq "current"
+ && istranslatable($link)
+ && istranslation($page)) {
+ my ($masterpage, $curlang) = ($page =~ /(.*)[.]([a-z]{2})$/);
+ return $link . "." . $curlang;
+ }
+ return $link;
+} #}}}
+
+# We use filter to convert PO to the master page's type,
+# since other plugins should not work on PO files
+sub filter (@) { #{{{
+ my %params = @_;
+ my $page = $params{page};
+ my $destpage = $params{destpage};
+ my $content = decode_utf8(encode_utf8($params{content}));
+
+ # decide if this is a PO file that should be converted into a translated document,
+ # and perform various sanity checks
+ if (! istranslation($page) || $filtered{$page}{$destpage}) {
+ return $content;
+ }
+
+ my ($masterpage, $lang) = ($page =~ /(.*)[.]([a-z]{2})$/);
+ my $file=srcfile(exists $params{file} ? $params{file} : $IkiWiki::pagesources{$page});
+ my $masterfile = srcfile($pagesources{$masterpage});
+ my (@pos,@masters);
+ push @pos,$file;
+ push @masters,$masterfile;
+ my %options = (
+ "markdown" => (pagetype($masterfile) eq 'mdwn') ? 1 : 0,
+ );
+ my $doc=Locale::Po4a::Chooser::new('text',%options);
+ $doc->process(
+ 'po_in_name' => \@pos,
+ 'file_in_name' => \@masters,
+ 'file_in_charset' => 'utf-8',
+ 'file_out_charset' => 'utf-8',
+ ) or error("[po/filter:$file]: failed to translate");
+ my $tmpfh = File::Temp->new(TEMPLATE => "/tmp/ikiwiki-po-filter-out.XXXXXXXXXX");
+ my $tmpout = $tmpfh->filename;
+ $doc->write($tmpout) or error("[po/filter:$file] could not write $tmpout");
+ $content = readfile($tmpout) or error("[po/filter:$file] could not read $tmpout");
+ $filtered{$page}{$destpage}=1;
+ return $content;
+} #}}}
+
+sub htmlize (@) { #{{{
+ my %params=@_;
+ my $page = $params{page};
+ my $content = $params{content};
+ my ($masterpage, $lang) = ($page =~ /(.*)[.]([a-z]{2})$/);
+ my $masterfile = srcfile($pagesources{$masterpage});
+
+ # force content to be htmlize'd as if it was the same type as the master page
+ return IkiWiki::htmlize($page, $page, pagetype($masterfile), $content);
+} #}}}
+
+sub percenttranslated ($) { #{{{
+ my $page=shift;
+ return "N/A" unless (istranslation($page));
+ my ($masterpage, $lang) = ($page =~ /(.*)[.]([a-z]{2})$/);
+ my $file=srcfile($pagesources{$page});
+ my $masterfile = srcfile($pagesources{$masterpage});
+ my (@pos,@masters);
+ push @pos,$file;
+ push @masters,$masterfile;
+ my %options = (
+ "markdown" => (pagetype($masterfile) eq 'mdwn') ? 1 : 0,
+ );
+ my $doc=Locale::Po4a::Chooser::new('text',%options);
+ $doc->process(
+ 'po_in_name' => \@pos,
+ 'file_in_name' => \@masters,
+ 'file_in_charset' => 'utf-8',
+ 'file_out_charset' => 'utf-8',
+ ) or error("[po/percenttranslated:$file]: failed to translate");
+ my ($percent,$hit,$queries) = $doc->stats();
+ return $percent;
+} #}}}
+
+sub otherlanguages ($) { #{{{
+ my $page=shift;
+ my @ret;
+ if (istranslatable($page)) {
+ foreach my $lang (sort keys %{$translations{$page}}) {
+ my $translation = $translations{$page}{$lang};
+ push @ret, {
+ url => urlto($translation, $page),
+ code => $lang,
+ language => $config{po_slave_languages}{$lang},
+ percent => percenttranslated($translation),
+ };
+ }
+ }
+ elsif (istranslation($page)) {
+ my ($masterpage, $curlang) = ($page =~ /(.*)[.]([a-z]{2})$/);
+ push @ret, {
+ url => urlto($masterpage, $page),
+ code => $config{po_master_language}{code},
+ language => $config{po_master_language}{name},
+ master => 1,
+ };
+ foreach my $lang (sort keys %{$translations{$masterpage}}) {
+ push @ret, {
+ url => urlto($translations{$masterpage}{$lang}, $page),
+ code => $lang,
+ language => $config{po_slave_languages}{$lang},
+ percent => percenttranslated($translations{$masterpage}{$lang}),
+ } unless ($lang eq $curlang);
+ }
+ }
+ return @ret;
+} #}}}
+
+sub pagetemplate (@) { #{{{
+ my %params=@_;
+ my $page=$params{page};
+ my $template=$params{template};
+
+ if (istranslation($page) && $template->query(name => "percenttranslated")) {
+ $template->param(percenttranslated => percenttranslated($page));
+ }
+ if ($template->query(name => "istranslation")) {
+ $template->param(istranslation => istranslation($page));
+ }
+ if ($template->query(name => "istranslatable")) {
+ $template->param(istranslatable => istranslatable($page));
+ }
+ if ($template->query(name => "otherlanguages")) {
+ $template->param(otherlanguages => [otherlanguages($page)]);
+ if (istranslatable($page)) {
+ foreach my $translation (values %{$translations{$page}}) {
+ add_depends($page, $translation);
+ }
+ }
+ elsif (istranslation($page)) {
+ my ($masterpage, $curlang) = ($page =~ /(.*)[.]([a-z]{2})$/);
+ add_depends($page, $masterpage);
+ foreach my $translation (values %{$translations{$masterpage}}) {
+ add_depends($page, $translation);
+ }
+ }
+ }
+} # }}}
+
+sub istranslatable ($) { #{{{
+ my $page=shift;
+ my $file=$pagesources{$page};
+
+ if (! defined $file
+ || (defined pagetype($file) && pagetype($file) eq 'po')
+ || $file =~ /\.pot$/) {
+ return 0;
+ }
+ return pagespec_match($page, $config{po_translatable_pages});
+} #}}}
+
+sub _istranslation ($) { #{{{
+ my $page=shift;
+ my $file=$pagesources{$page};
+ if (! defined $file) {
+ return IkiWiki::FailReason->new("no file specified");
+ }
+
+ if (! defined $file
+ || ! defined pagetype($file)
+ || ! pagetype($file) eq 'po'
+ || $file =~ /\.pot$/) {
+ return 0;
+ }
+
+ my ($masterpage, $lang) = ($page =~ /(.*)[.]([a-z]{2})$/);
+ if (! defined $masterpage || ! defined $lang
+ || ! (length($masterpage) > 0) || ! (length($lang) > 0)
+ || ! defined $pagesources{$masterpage}
+ || ! defined $config{po_slave_languages}{$lang}) {
+ return 0;
+ }
+
+ return istranslatable($masterpage);
+} #}}}
+
+sub istranslation ($) { #{{{
+ my $page=shift;
+ if (_istranslation($page)) {
+ my ($masterpage, $lang) = ($page =~ /(.*)[.]([a-z]{2})$/);
+ $translations{$masterpage}{$lang}=$page unless exists $translations{$masterpage}{$lang};
+ return 1;
+ }
+ return 0;
+} #}}}
+
+package IkiWiki::PageSpec;
+use warnings;
+use strict;
+use IkiWiki 2.00;
+
+sub match_istranslation ($;@) { #{{{
+ my $page=shift;
+ if (IkiWiki::Plugin::po::istranslation($page)) {
+ return IkiWiki::SuccessReason->new("is a translation page");
+ }
+ else {
+ return IkiWiki::FailReason->new("is not a translation page");
+ }
+} #}}}
+
+sub match_istranslatable ($;@) { #{{{
+ my $page=shift;
+ if (IkiWiki::Plugin::po::istranslatable($page)) {
+ return IkiWiki::SuccessReason->new("is set as translatable in po_translatable_pages");
+ }
+ else {
+ return IkiWiki::FailReason->new("is not set as translatable in po_translatable_pages");
+ }
+} #}}}
+
+sub match_lang ($$;@) { #{{{
+ my $page=shift;
+ my $wanted=shift;
+ my $regexp=IkiWiki::glob2re($wanted);
+ my $lang;
+ my $masterpage;
+
+ if (IkiWiki::Plugin::po::istranslation($page)) {
+ ($masterpage, $lang) = ($page =~ /(.*)[.]([a-z]{2})$/);
+ }
+ else {
+ $lang = $config{po_master_language}{code};
+ }
+
+ if ($lang!~/^$regexp$/i) {
+ return IkiWiki::FailReason->new("file language is $lang, not $wanted");
+ }
+ else {
+ return IkiWiki::SuccessReason->new("file language is $wanted");
+ }
+} #}}}
+
+sub match_currentlang ($$;@) { #{{{
+ my $page=shift;
+ shift;
+ my %params=@_;
+ my ($currentmasterpage, $currentlang, $masterpage, $lang);
+
+ return IkiWiki::FailReason->new("no location provided") unless exists $params{location};
+
+ if (IkiWiki::Plugin::po::istranslation($params{location})) {
+ ($currentmasterpage, $currentlang) = ($params{location} =~ /(.*)[.]([a-z]{2})$/);
+ }
+ else {
+ $currentlang = $config{po_master_language}{code};
+ }
+
+ if (IkiWiki::Plugin::po::istranslation($page)) {
+ ($masterpage, $lang) = ($page =~ /(.*)[.]([a-z]{2})$/);
+ }
+ else {
+ $lang = $config{po_master_language}{code};
+ }
+
+ if ($lang eq $currentlang) {
+ return IkiWiki::SuccessReason->new("file language is the same as current one, i.e. $currentlang");
+ }
+ else {
+ return IkiWiki::FailReason->new("file language is $lang, whereas current language is $currentlang");
+ }
+} #}}}
+
+1
diff --git a/IkiWiki/Plugin/skeleton.pm.example b/IkiWiki/Plugin/skeleton.pm.example
index f844ddb91..ecf2a2407 100644
--- a/IkiWiki/Plugin/skeleton.pm.example
+++ b/IkiWiki/Plugin/skeleton.pm.example
@@ -34,6 +34,8 @@ sub import { #{{{
hook(type => "formbuilder_setup", id => "skeleton", call => \&formbuilder_setup);
hook(type => "formbuilder", id => "skeleton", call => \&formbuilder);
hook(type => "savestate", id => "skeleton", call => \&savestate);
+ hook(type => "targetpage", id => "skeleton", call => \&targetpage);
+ hook(type => "urlpath", id => "skeleton", call => \&urlpath);
} # }}}
sub getopt () { #{{{
@@ -204,4 +206,12 @@ sub savestate () { #{{{
debug("skeleton plugin running in savestate");
} #}}}
+sub targetpage () { #{{{
+ debug("skeleton plugin running in targetpage");
+} #}}}
+
+sub urlpath () { #{{{
+ debug("skeleton plugin running in urlpath");
+} #}}}
+
1
diff --git a/doc/ikiwiki/pagespec/po.mdwn b/doc/ikiwiki/pagespec/po.mdwn
new file mode 100644
index 000000000..2edfaa0c1
--- /dev/null
+++ b/doc/ikiwiki/pagespec/po.mdwn
@@ -0,0 +1,16 @@
+[[!if test="enabled(po)"
+ then="This wiki has po support **enabled**."
+ else="This wiki has po support **disabled**."]]
+
+If the [[po|plugins/po]] plugin is enabled, the regular
+[[ikiwiki/PageSpec]] syntax is expanded with the following additional
+tests that can be used to improve user navigation in a multi-lingual
+wiki:
+
+* "`lang(LL)`" - Tests whether a page is written in the language
+ specified as a ISO639-1 (two-letter) language code.
+* "`currentlang()`" - Tests whether a page is written in the same
+ language as the current page.
+
+Note: every non-PO page is considered to be written in
+`po_master_language`, as specified in `ikiwiki.setup`.
diff --git a/doc/plugins/po.mdwn b/doc/plugins/po.mdwn
new file mode 100644
index 000000000..1412cfea2
--- /dev/null
+++ b/doc/plugins/po.mdwn
@@ -0,0 +1,300 @@
+[[!template id=plugin name=po core=0 author="[[intrigeri]]"]]
+[[!tag type/format]]
+
+This plugin adds support for multi-lingual wikis, translated with
+gettext, using [po4a](http://po4a.alioth.debian.org/).
+
+It depends on the Perl `Locale::Po4a::Po` library (`apt-get install po4a`).
+
+Introduction
+============
+
+A language is chosen as the "master" one, and any other supported
+language is a "slave" one.
+
+A page written in the "master" language is a "master" page. It can be
+of any page type supported by ikiwiki, but PO. It does not have to be
+named a special way: migration to this plugin does not imply any page
+renaming work.
+
+Example: `bla/page.mdwn` is a "master" Markdown page written in
+English; if `usedirs` is enabled, it is rendered as
+`bla/page/index.en.html`, else as `bla/page.en.html`.
+
+Any translation of a "master" page into a "slave" language is called
+a "slave" page; it is written in the gettext PO format. PO is now
+a page type supported by ikiwiki.
+
+Example: `bla/page.fr.po` is the PO "message catalog" used to
+translate `bla/page.mdwn` into French; if `usedirs` is enabled, it is
+rendered as `bla/page/index.fr.html`, else as `bla/page.fr.html`
+
+
+Configuration
+=============
+
+Supported languages
+-------------------
+
+`po_master_language` is used to set the "master" language in
+`ikiwiki.setup`, such as:
+
+ po_master_language => { 'code' => 'en', 'name' => 'English' }
+
+`po_slave_languages` is used to set the list of supported "slave"
+languages, such as:
+
+ po_slave_languages => { 'fr' => 'Français',
+ 'es' => 'Castellano',
+ 'de' => 'Deutsch',
+ }
+
+Decide which pages are translatable
+-----------------------------------
+
+The `po_translatable_pages` setting configures what pages are
+translatable. It is a [[ikiwiki/PageSpec]], so you have lots of
+control over what kind of pages are translatable.
+
+The PO translations files are anyway not considered as being
+translatable, so you don't need to worry about excluding them
+explicitly from this [[ikiwiki/PageSpec]].
+
+Internal links
+--------------
+
+The `po_link_to` option in `ikiwiki.setup` is used to decide how
+internal links should be generated, depending on web server features
+and site-specific preferences.
+
+### Default linking behavior
+
+If `po_link_to` is unset, or set to `default`, ikiwiki's default
+linking behavior is preserved: `\[[destpage]]` links to the master
+language's page.
+
+### Link to current language
+
+If `po_link_to` is set to `current`, `\[[destpage]]` links to the
+`destpage`'s version written in the current page's language, if
+available, *i.e.*:
+
+- `foo/destpage/index.LL.html` if `usedirs` is enabled
+- `foo/destpage.LL.html` if `usedirs` is disabled
+
+### Link to negotiated language
+
+If `po_link_to` is set to `negotiated`, `\[[page]]` links to the
+negotiated preferred language, *i.e.* `foo/page/`.
+
+(In)compatibility notes:
+
+- if `usedirs` is disabled, it does not make sense to set `po_link_to`
+ to `negotiated`; this option combination is neither implemented
+ nor allowed.
+- if the web server does not support Content Negotiation, setting
+ `po_link_to` to `negotiated` will produce a unusable website.
+
+
+Server support
+==============
+
+Apache
+------
+
+Using Apache `mod_negotiation` makes it really easy to have Apache
+serve any page in the client's preferred language, if available.
+This is the default Debian Apache configuration.
+
+When `usedirs` is enabled, one has to set `DirectoryIndex index` for
+the wiki context.
+
+Setting `DefaultLanguage LL` (replace `LL` with your default MIME
+language code) for the wiki context can help to ensure
+`bla/page/index.en.html` is served as `Content-Language: LL`.
+
+lighttpd
+--------
+
+lighttpd unfortunately does not support content negotiation.
+
+**FIXME**: does `mod_magnet` provide the functionality needed to
+ emulate this?
+
+
+Usage
+=====
+
+Templates
+---------
+
+The `ISTRANSLATION` and `ISTRANSLATABLE` variables can be used to
+display things only on translatable or translation pages.
+
+### Display page's versions in other languages
+
+The `OTHERLANGUAGES` loop provides ways to display other languages'
+versions of the same page, and the translations' status.
+
+One typically adds the following code to `templates/page.tmpl`:
+
+ <TMPL_IF NAME="OTHERLANGUAGES">
+ <div id="otherlanguages">
+ <ul>
+ <TMPL_LOOP NAME="OTHERLANGUAGES">
+ <li>
+ <a href="<TMPL_VAR NAME="URL">"><TMPL_VAR NAME="LANGUAGE"></a>
+ <TMPL_UNLESS NAME="MASTER">
+ (<TMPL_VAR NAME="PERCENT">&nbsp;%)
+ </TMPL_UNLESS>
+ </li>
+ </TMPL_LOOP>
+ </ul>
+ </div>
+ </TMPL_IF>
+
+The following variables are available inside the loop (for every page in):
+
+- `URL` - url to the page
+- `CODE` - two-letters language code
+- `LANGUAGE` - language name (as defined in `po_slave_languages`)
+- `MASTER` - is true (1) if, and only if the page is a "master" page
+- `PERCENT` - for "slave" pages, is set to the translation completeness, in percents
+
+### Display the current translation status
+
+The `PERCENTTRANSLATED` variable is set to the translation
+completeness, expressed in percent, on "slave" pages.
+
+One can use it this way:
+
+ <TMPL_IF NAME="ISTRANSLATION">
+ <div id="percenttranslated">
+ <TMPL_VAR NAME="PERCENTTRANSLATED">
+ </div>
+ </TMPL_IF>
+
+Additional PageSpec tests
+-------------------------
+
+This plugin enhances the regular [[ikiwiki/PageSpec]] syntax with some
+additional tests that are documented [[here|ikiwiki/pagespec/po]].
+
+Automatic PO files update
+-------------------------
+
+Committing changes to a "master" page:
+
+1. updates the POT file and the PO files for the supported languages
+ (this is done in the `needsbuild` hook); the updated PO files are
+ then put under version control
+2. triggers a refresh of the corresponding HTML slave pages (this is
+ achieved by making any "slave" page dependent on the corresponding
+ "master" page, in the `needsbuild` hook)
+
+Also, when the plugin has just been enabled, or when a page has just
+been declared as being translatable, the needed POT and PO files are
+created, and the PO files are checked into version control.
+
+TODO
+====
+
+OTHERLANGUAGES dependencies
+---------------------------
+
+Pages using `OTHERLANGUAGES` depend on any "master" and "slave" pages
+whose status is being displayed. It is supposed to trigger dependency
+loops, but no practical bugs were noticed yet.
+
+Should pages using the `OTHERLANGUAGES` template loop be declared as
+linking to the same page in other versions? To be rigorous, they
+should, but this may clutter the backlinks.
+
+Security checks
+---------------
+
+- `refreshpofiles` uses `system()`, whose args have to be checked more
+ thoroughly to prevent any security issue (command injection, etc.).
+- `refreshpofiles` and `refreshpot` create new files; this may need
+ some checks, e.g. using `IkiWiki::prep_writefile()`
+
+gettext/po4a rough corners
+--------------------------
+
+- fix the duplicated PO header mysterious bug
+- fix the "duplicate message definition" error when updating a PO
+ file; do PO files need normalizing? (may be a side effect of
+ previous bug)
+- fix infinite loop when synchronizing two ikiwiki (when checkouts
+ live in different directories): say bla.fr.po has been updated in
+ repo2; pulling repo2 from repo1 seems to trigger a PO update, that
+ changes bla.fr.po in repo1; then pushing repo1 to repo2 triggers
+ a PO update, that changes bla.fr.po in repo2; etc.; fixed in
+ `629968fc89bced6727981c0a1138072631751fee` ?
+
+Misc. improvements
+------------------
+
+### automatic POT/PO update
+
+Use the `change` hook instead of `needsbuild`?
+
+### page titles
+
+Use nice page titles from meta plugin in links, as inline already does.
+
+### websetup
+
+Which configuration settings are safe enough for websetup?
+
+Translation quality assurance
+-----------------------------
+
+Modifying a PO file via the CGI must be forbidden if the new version
+is not a valid PO file. As a bonus, check that it provides a more
+complete translation than the existing one.
+
+A new `cansave` type of hook would be needed to implement this.
+
+Note: committing to the underlying repository is a way to bypass
+this check.
+
+Translating online
+------------------
+
+As PO is a wiki page type, we already have an online PO editor, that
+is ikiwiki's CGI.
+
+**FIXME** preview does not work for PO files.
+
+A message-by-message interface could also be implemented at some
+point; a nice way to do offline translation work (without VCS access)
+still has to be offered, though.
+
+Translating offline without VCS access
+--------------------------------------
+
+The following workflow should be made possible for translators without
+VCS access who need to edit the PO files in another editor than a web
+browser:
+
+- download the page's PO file
+- use any PO editor to update the translation
+- upload the updated PO file
+
+Implementation note: a generic mechanism to upload a page's source is
+needed: it's only an alternative way to allow saving a the modified
+page's source with the CGI.
+
+### Short-term workflow
+
+A possible workaround is:
+
+- pretend to edit the PO file online
+- copy the PO file content from the textarea
+- cancel the edit
+- paste the content into a local file.
+- edit the local file in any PO editor
+- pretend to edit the PO file online
+- paste the modified local file's content into the edit textarea
+- save
diff --git a/doc/plugins/write.mdwn b/doc/plugins/write.mdwn
index 856b34ba1..857d176d5 100644
--- a/doc/plugins/write.mdwn
+++ b/doc/plugins/write.mdwn
@@ -434,6 +434,36 @@ describes the plugin as a whole. For example:
and undef if a rebuild could be needed in some circumstances, but is not
strictly required.
+### targetpage
+
+ hook(type => "targetpage", id => "foo", call => \&targetpage);
+
+This hook can be used to override the name of the file a page should
+be compiled into.
+
+It should return the target filename.
+
+### tweakurlpath
+
+ hook(type => "tweakurlpath", id => "foo", call => \&tweakurlpath);
+
+This hook can be used to modify the internal urls generated by
+ikiwiki; it is run just after ikiwiki has removed the trailing
+`index.html`, in case `usedirs` is enabled.
+
+It should return the modified url.
+
+### tweakbestlink
+
+ hook(type => "tweakbestlink", id => "foo", call => \&tweakbestlink);
+
+This hook can be used to modify the page returned by `bestlink`. It is
+passed named parameters `page` and `link`. These are, respectively,
+the page where the link will appear and the link ikiwiki would choose
+as the best one, if no `tweakbestlink` hook was in effect.
+
+It should return the modified link.
+
## Plugin interface
To import the ikiwiki plugin interface:
diff --git a/t/syntax.t b/t/syntax.t
index d09d17f7f..8c96d1d84 100755
--- a/t/syntax.t
+++ b/t/syntax.t
@@ -6,7 +6,7 @@ use Test::More;
my @progs="ikiwiki.in";
my @libs="IkiWiki.pm";
# monotone, external, amazon_s3 skipped since they need perl modules
-push @libs, map { chomp; $_ } `find IkiWiki -type f -name \\*.pm | grep -v monotone.pm | grep -v external.pm | grep -v amazon_s3.pm`;
+push @libs, map { chomp; $_ } `find IkiWiki -type f -name \\*.pm | grep -v monotone.pm | grep -v external.pm | grep -v amazon_s3.pm | grep -v po.pm`;
push @libs, 'IkiWiki/Plugin/skeleton.pm.example';
plan(tests => (@progs + @libs));
generated by cgit v1.2.3 (git 2.39.1) at 2024-07-08 12:10:40 +0000