Split apache404 into an independent plugin

Also make it ignore the 'do' parameter at Joey's suggestion, to have one
less thing to remember when configuring.

2 files changed, 77 insertions, 48 deletions

diff --git a/IkiWiki/CGI.pm b/IkiWiki/CGI.pm
index 8734cdd49..e75ebcd27 100644
--- a/IkiWiki/CGI.pm
+++ b/IkiWiki/CGI.pm
@@ -338,46 +338,6 @@ sub cgi_goto ($;$) {
 	exit;
 }
 
-sub cgi_page_from_404 ($$$) {
-	my $path = shift;
-	my $baseurl = shift;
-	my $usedirs = shift;
-
-	# fail if missing from environment or whatever
-	return undef unless defined $path;
-	return undef unless defined $baseurl;
-
-	# with usedirs on, path is like /~fred/foo/bar/ or /~fred/foo/bar or
-	#    /~fred/foo/bar/index.html
-	# with usedirs off, path is like /~fred/foo/bar.html
-	# baseurl is like 'http://people.example.com/~fred'
-
-	# convert baseurl to ~fred
-	unless ($baseurl =~ s{^https?://[^/]+/?}{}) {
-		return undef;
-	}
-
-	# convert path to /~fred/foo/bar
-	if ($usedirs) {
-		$path =~ s/\/*(?:index\.$config{htmlext})?$//;
-	}
-	else {
-		$path =~ s/\.$config{htmlext}$//;
-	}
-
-	# remove /~fred/
-	unless ($path =~ s{^/*\Q$baseurl\E/*}{}) {
-		return undef;
-	}
-
-	# special case for the index
-	unless ($path) {
-		return 'index';
-	}
-
-	return $path;
-}
-
 sub cgi (;$$) {
 	my $q=shift;
 	my $session=shift;
@@ -409,14 +369,7 @@ sub cgi (;$$) {
 	# commenter are for compatibility with any saved URLs
 	if ($do eq 'goto' || $do eq 'recentchanges_link' ||
 	    $do eq 'commenter') {
-		my $page = undef;
-
-		if ($ENV{REDIRECT_STATUS} eq '404') {
-			$page = cgi_page_from_404($ENV{REDIRECT_URL},
-				$config{url}, $config{usedirs});
-		}
-
-		cgi_goto($q, $page);
+		cgi_goto($q);
 	}
 
 	# Need to lock the wiki before getting a session.
diff --git a/IkiWiki/Plugin/apache404.pm b/IkiWiki/Plugin/apache404.pm
new file mode 100644
index 000000000..3ac6b3af5
--- /dev/null
+++ b/IkiWiki/Plugin/apache404.pm
@@ -0,0 +1,76 @@
+#!/usr/bin/perl
+# Copyright © 2009 Simon McVittie <http://smcv.pseudorandom.co.uk/>
+# Licensed under the GNU GPL, version 2, or any later version published by the
+# Free Software Foundation
+package IkiWiki::Plugin::apache404;
+
+use warnings;
+use strict;
+use IkiWiki 3.00;
+
+sub import {
+	hook(type => "cgi", id => 'apache404',  call => \&cgi);
+}
+
+sub getsetup () {
+	return
+		plugin => {
+			# not really a matter of safety, but enabling/disabling
+			# through a web interface is useless - it needs web
+			# server admin action too
+			safe => 0,
+			rebuild => 0,
+		}
+}
+
+sub cgi_page_from_404 ($$$) {
+	my $path = shift;
+	my $baseurl = shift;
+	my $usedirs = shift;
+
+	# fail if missing from environment or whatever
+	return undef unless defined $path;
+	return undef unless defined $baseurl;
+
+	# with usedirs on, path is like /~fred/foo/bar/ or /~fred/foo/bar or
+	#    /~fred/foo/bar/index.html
+	# with usedirs off, path is like /~fred/foo/bar.html
+	# baseurl is like 'http://people.example.com/~fred'
+
+	# convert baseurl to ~fred
+	unless ($baseurl =~ s{^https?://[^/]+/?}{}) {
+		return undef;
+	}
+
+	# convert path to /~fred/foo/bar
+	if ($usedirs) {
+		$path =~ s/\/*(?:index\.$config{htmlext})?$//;
+	}
+	else {
+		$path =~ s/\.$config{htmlext}$//;
+	}
+
+	# remove /~fred/
+	unless ($path =~ s{^/*\Q$baseurl\E/*}{}) {
+		return undef;
+	}
+
+	# special case for the index
+	unless ($path) {
+		return 'index';
+	}
+
+	return $path;
+}
+
+sub cgi ($) {
+	my $cgi=shift;
+
+	if ($ENV{REDIRECT_STATUS} eq '404') {
+		my $page = cgi_page_from_404($ENV{REDIRECT_URL},
+			$config{url}, $config{usedirs});
+		IkiWiki::cgi_goto($cgi, $page);
+	}
+}
+
+1;